IF function with array

[tigerzen]

Need some help with this, I think I'm close but need something to connect C10 the headings and need a single figure rather than the array that I'm getting in cell D10.

Book1
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q	R	S	T	U	V
1		Opponent	Result	KI For	KI Against	KI Diff	MK	MK For	MK Against	MK Diff	HB	HB For	HB Against	HB Diff	DI	DI For	DI Against	DI Diff	GL	GL For	GL Against	GL Diff
2	R1	Team A	D	228	221	7	95-97	95	97	-2	121-120	121	120	1	349-341	349	341	8	8-8	8	8	0
3	R2	Team B	W	209	216	-7	94-94	94	94	0	139-142	139	142	-3	348-358	348	358	-10	17-10	17	10	7
4	R3	Team C	L	219	229	-10	76-65	76	65	11	137-171	137	171	-34	356-400	356	400	-44	7-8	7	8	-1
5	R4	Team D	W	218	239	-21	72-93	72	93	-21	174-125	174	125	49	392-364	392	364	28	12-12	12	12	0
6	R5	Team E	W	217	238	-21	85-88	85	88	-3	164-129	164	129	35	381-367	381	367	14	11-18	11	18	-7
7	R6	Team F	W	223	215	8	81-103	81	103	-22	136-166	136	166	-30	349-381	349	381	-32	11-15	11	15	-4
8	R7	Team G	L	200	254	-54	96-135	96	135	-39	139-126	139	126	13	339-380	339	380	-41	6-11	6	11	-5
9
10			KI Diff			1
11			MK Diff
12			HB Diff
13			DI Diff
14			GL Diff
15
16			Desired
17			KI Diff	1
18			MK Diff	0
19			HB Diff	2
20			DI Diff	2
21			GL Diff	1
Sheet1

Cell Formulas
Range	Formula
C10:C14,C17:C21	C10	=TRANSPOSE(FILTER($D$1:$CH$1,RIGHT($D$1:$CH$1,4)="Diff",""))
D10:V10	D10	=IF(C10=$D$1:$V$1,COUNTIFS($C$2:$C$8,"W",$F$2:$F$8,">0"),"")
Dynamic array formulas.

 

[Fluff]

How about

=BYROW(C10#,LAMBDA(br,COUNTIFS($C$2:$C$8,"W",INDEX($F$2:$V$8,,XMATCH(br,F1:V1)),">0")))

 

[tigerzen]

Thanks Fluff, would you mind giving me the Excel 2019 solution if possible?

 

[Fluff]

If you need a formula to work in versions other than your profile then you should say so at the the start.
Try

=COUNTIFS($C$2:$C$8,"W",INDEX($F$2:$V$8,,MATCH(C10,$F$1:$V$1,0)),">0")

 

[tigerzen]

If you need a formula to work in versions other than your profile then you should say so at the the start.
Try

=COUNTIFS($C$2:$C$8,"W",INDEX($F$2:$V$8,,MATCH(C10,$F$1:$V$1,0)),">0")

Thanks Fluff, my apologies, I had meant to mention the earlier version but I forgot to.

 

[Fluff]

Glad to help & thanks for the feedback.