Looking for the Max value within subgroups of a list

[ChuckDrago]

Hi everyone,
I am trying to use the combo filter and max but get unwanted results due to filtered ranges not being properly coded. My fault.
The data structure is Segment, Discipline, TValue, and the populated data are:
1) Segment = 1 to 10
2) For each segment, 3 possible disciplines = Forward, Rest, Backward
3) For each discipline there are many values, of which I need to extract the Maximum for only Fwd and Bwd
The attached table exemplifies the sought end result, Notice that Forward are positive values and Backward are negative ones.
Thank you all very much,
Chuck

Segment	Max Forward	Max Backward
1	23.4	-21
2	26.1	-23.1
3	25.0	-25.0
4	26.5	-25.8

 

[KRice]

Could you post a short example showing the layout of the data...where the Segments, Disciplines, and TValues are shown? And to clarify, do you want the maximum values for Fwd and Bwd for all records, regardless of whether they appear in a filtered list, or do you want the max values for only those records appearing in the filtered list?

 

[KRice]

I'm making a guess about the layout, but here is one idea using the AGGREGATE function:

Book2
	A	B	C	D	E	F	G
1	Segment	Discipline	Tvalue
2	1	Forward	10		Segment	Max Forward	Max Backward
3	1	Rest	27		1	30	-35
4	1	Backward	-25		2	64	-77
5	2	Backward	-67		3	109	-200
6	2	Forward	64		4	6	-4
7	1	Backward	-15
8	2	Forward	34
9	3	Forward	109
10	3	Backward	-100
11	3	Rest	-150
12	1	Backward	-35
13	3	Forward	99
14	2	Backward	-77
15	1	Forward	30
16	3	Backward	-200
17	1	Forward	20
18	1	Rest	17
19	2	Backward	-57
20	2	Forward	24
21	2	Rest	14
22	4	Backward	-3
23	4	Backward	-4
24	4	Forward	5
25	4	Forward	6
26	4	Rest	8
27	4	Rest	9
ChuckDrago

Cell Formulas
Range	Formula
F3:F6	F3	=AGGREGATE(14,3,($C$2:$C$27)/(($A$2:$A$27=$E3)*($B$2:$B$27="Forward")),1)
G3:G6	G3	=AGGREGATE(15,3,($C$2:$C$27)/(($A$2:$A$27=$E3)*($B$2:$B$27="Backward")),1)

 

[ChuckDrago]

Hi KRice, and thanks for your help.
Attached is a sample of the DB, although the numbers are just shown for illustration.
Chuck

 

[KRice]

Thanks for the layout clarification. Here is a modified version:

Book2
	A	B	C	D	E	F	G	H
1	Segment	Forward	Backward	Rest
2	1	10	-25	27		Segment	Max Forward	Max Backward
3	1	30	-15	17		1	30	-35
4	1	20	-35			2	64	-77
5	2	64	-67			3	109	-200
6	2	34	-77			4	6	-4
7	2	24	-57	14
8	3	109	-100	-150
9	3	99	-200	22
10	4	5	-3	8
11	4	6	-4	9
ChuckDrago (2)

Cell Formulas
Range	Formula
G3:G6	G3	=AGGREGATE(14,3,($B$2:$B$11)/($A$2:$A$11=$F3),1)
H3:H6	H3	=AGGREGATE(15,3,($C$2:$C$11)/($A$2:$A$11=$F3),1)

 

[ChuckDrago]

Much obliged KRice... Easier than I thought.
Chuck

 

[KRice]

Glad to help...thanks for the feedback.