Macro that selects and deletes a file in Excel for Mac

[Aretradeser]

I use Microsoft® Excel for Mac, Version 16.83 (24031120), Office LTSC Standard for Mac 2021.
I have designed a code to open a dialog box and allow me to select any file; and, once selected, to give me the option to move it to the trash. Everything seems to work correctly showing, via a screen, that; "The file has been moved to the trash successfully." But it hasn't actually moved it to the bin, it's still in the same place.
How can I fix this problem and have it actually move /Delete the file I have selected?
This is the code:

Sub SelectAndDeleteFile()
    Dim RutaArchivo As String
    Dim Respuesta As Integer
    ' Select file
    RutaArchivo = MacScript("return POSIX path of (choose file)")
    
    If RutaArchivo <> "" Then
        Respuesta = MsgBox("¿Surely you want to move the file to the trash?", vbYesNo + vbQuestion, "Confirmation")
        If Respuesta = vbYes Then
            On Error Resume Next
            Kill RutaArchivo ' Delete the file (move to trash)
            If Err.Number = 0 Then
                MsgBox "The file has been successfully moved to the Trash..", vbInformation, "File Deleted"
            Else
                MsgBox "Failed to move file to trash.", vbExclamation, "Error"
            End If
            On Error GoTo 0
        End If
    End If
End Sub

 

[Micron]

I have never coded for Mac so maybe this won't help. First, I'd comment out the On Error Resume Next and re-test to be sure that isn't the problem. Then there is this:

Use VBA Kill to delete files

If you use the Kill command on a Mac be aware that there is a file name(with extension) limit of 32 characters. Be sure that you use shorte...

office-2all.blogspot.com

 

[Tetra201]

Try implementing the following changes:

...
RutaArchivo = MacScript("return POSIX path of (choose file) as String")
...
' Instead of Kill, use
MacScript "tell application ""Finder"" to delete """ & RutaArchivo & """"
...

 

[Aretradeser]

Try implementing the following changes:

...
RutaArchivo = MacScript("return POSIX path of (choose file) as String")
...
' Instead of Kill, use
MacScript "tell application ""Finder"" to delete """ & RutaArchivo & """"
...

The modifications you propose have been carried out, it still does not work. It does not delete the file. I attach a screenshot

 

[Tetra201]

Unfortunately, I cannot be of further help to you as I have an older version of Excel for Mac (14.7.7) where the suggested changes were tested to work. Hope someone with a newer version will chime in.

 

[Aretradeser]

Thank you very much, Tetra201. In the end, I have come up with the solution, which is to use a script, within the code, that allows me to delete the file, and with the rest of the code to open a dialog box and allow me to select any file. I leave you the complete code in case you need it.
I also want to thank Micron, for his valuable contribution that has allowed me to complete this code.

Sub DeleteFile()
    Dim RutaArchivo As String
    Dim scriptToRun As String
    Dim Respuesta As Integer
    
    ' Select file
    RutaArchivo = MacScript("return POSIX path of (choose file) as String")
    
    If RutaArchivo <> "" Then
        Respuesta = MsgBox("¿Are you sure you want to delete the file?", vbYesNo + vbQuestion, "Confirmation")
        If Respuesta = vbYes Then
            ' Build AppleScript script to delete the selected file
            scriptToRun = "do shell script ""rm "" & quoted form of POSIX path of """ & RutaArchivo & """"
            
            ' Execute AppleScript script
            On Error Resume Next
            MacScript scriptToRun
            If Err.Number = 0 Then
                MsgBox "The file has been successfully deleted.", vbInformation, "File Deleted"
            Else
                MsgBox "Error deleting file.", vbExclamation, "Error"
            End If
            On Error GoTo 0
        End If
    End If
End Sub