Missing Bracket in Formula

[kumara_faith]

Hi,

I have the following formula which excel keep saying error in formula. Am I missing any brackets here ? Appreciate any help.

=IFERROR(((F41*$F$3)+(G41*$G$3)+(H41*$H$3)+(I41*$I$3)+(J41*$J$3)+(K41*$K$3)+(L41*$L$3)+(M41*$M$3)+(N41*$N$3)+(O41*$O$3)+(P41*$P$3)+(Q41*$Q$3)+(R41*$R$3)+(S41*$S$3)+(T41*$T$3)+(U41*$U$3)+(V41*$V$3)+(W41*$W$3)+(X41*$X$3))/((XLOOKUP(Jan!E41,'Lookup Tables'!$AD$3:$AD$17,'Lookup Tables'!$AE$3:$AE$17))*(COUNTIF(Y7:Y40,">0%")),0))))

 

[bebo021999]

Not test, but try
Lat 2 string
))
change to
),"")

 

[kumara_faith]

Hi,

Sorry, I did not get it. You mean change as follows?

=IFERROR(((F41*$F$3)+(G41*$G$3)+(H41*$H$3)+(I41*$I$3)+(J41*$J$3)+(K41*$K$3)+(L41*$L$3)+(M41*$M$3)+(N41*$N$3)+(O41*$O$3)+(P41*$P$3)+(Q41*$Q$3)+(R41*$R$3)+(S41*$S$3)+(T41*$T$3)+(U41*$U$3)+(V41*$V$3)+(W41*$W$3)+(X41*$X$3))/((XLOOKUP(Jan!E41,'Lookup Tables'!$AD$3:$AD$17,'Lookup Tables'!$AE$3:$AE$17))*(COUNTIF(Y7:Y40,">0%"),"")

 

[Dave Patton]

I did not use all of your formula.
Try just using brackets where they are required; see B7 below. Alternatively, use SumProduct
Build the numerator and test then build the denominator and test.
Then combine the formulas.

T202212a.xlsm
	B	C	D
7	200	200
2e

Cell Formulas
Range	Formula
B7	B7	=F41*$F$3+G41*$G$3+H41*$H$3+I41*$I$3+J41*$J$3+K41*$K$3+L41*$L$3+M41*$M$3+N41*$N$3+O41*$O$3
C7	C7	=SUMPRODUCT(F3:O3,F41:O41)

 

[Alex Blakenburg]

Assuming you want the Xlookup * by the countif before doing the division. This is what the corrected version looks like in the new Advanced Formula Environment.

=IFERROR(
    (
        (F41 * $F$3) + (G41 * $G$3) + (H41 * $H$3) + (I41 * $I$3) +
            (J41 * $J$3) + (K41 * $K$3) + (L41 * $L$3) + (M41 * $M$3) +
            (N41 * $N$3) + (O41 * $O$3) + (P41 * $P$3) + (Q41 * $Q$3) +
            (R41 * $R$3) + (S41 * $S$3) + (T41 * $T$3) + (U41 * $U$3) +
            (V41 * $V$3) + (W41 * $W$3) + (X41 * $X$3)
    ) /
        (
            XLOOKUP(
                Jan!E41,
                'Lookup Tables'!$AD$3:$AD$17,
                'Lookup Tables'!$AE$3:$AE$17
            ) * (COUNTIF(Y7:Y40, ">0%"))
        ),
    0
)

 

[Alex Blakenburg]

If you are sure that all your users have MS365 then Dave's sumproduct can be simplified to.

=SUM(F3:X3*F41:X41)

 

[kumara_faith]

Thank you Dave, Bebo and Alex. Appreciate it. Have a great day ahead

 

[Alex Blakenburg]

Thank you for acknowledging all the contributors. Glad we could help.