modified code on userform

[Alaa mg]

hello
I need adding currency to textbox when populate values in textbox based on name optionbutton name
optionbutton1 is DL and optionbutton2 RMT name so when populate the values in textbox should like this

Option Explicit

Private Sub UserForm_Initialize()
    Me.ComboBox1.RowSource = ""
    With Sheets("sh1").Cells(1).CurrentRegion
        Me.ComboBox1.List = .Columns("b:e").Offset(1).Resize(.Rows.Count - 1).Value
    End With
End Sub

Private Sub OptionButton1_Click()
    If Me.OptionButton1 Then
        If Me.ComboBox1.ListIndex > -1 Then ComboBox1_Change
    End If
End Sub

Private Sub OptionButton2_Click()
    If Me.OptionButton2 Then
        If Me.ComboBox1.ListIndex > -1 Then ComboBox1_Change
    End If
End Sub

Private Sub ComboBox1_Change()
    Dim i As Long
    If Me.ComboBox1.ListIndex = -1 Then Exit Sub
    If (Not Me.OptionButton1) * (Not Me.OptionButton2) Then
        MsgBox "Select Option first", vbCritical: Exit Sub
    End If
    With Me.ComboBox1
        For i = 0 To 2
            Me("textbox" & i + 1) = Format$(.List(.ListIndex, i), "#,##0.00;;@")
            If (i = 2) * (Me.OptionButton2) Then
                Me("textbox" & i + 1) = Format$(.List(.ListIndex, i + 1), "#,##0.00")
            End If
        Next
        Me.TextBox4 = Format$(Val(.List(.ListIndex, 1)) * Val(.List(.ListIndex, 2 + IIf(Me.OptionButton1, 0, 1))), "#,##0.00")
    End With
End Sub

 

[DanteAmor]

Change this line:

Me.TextBox4 = Format$(Val(.List(.ListIndex, 1)) * Val(.List(.ListIndex, 2 + IIf(Me.OptionButton1, 0, 1))), "#,##0.00")

By these lines:

dim prfix As String
prfix = IIf(OptionButton1, OptionButton1.Caption, OptionButton2.Caption)
Me.TextBox4 = prfix & " " & Format$(Val(.List(.ListIndex, 1)) * Val(.List(.ListIndex, 2 + IIf(Me.OptionButton1, 0, 1))), "#,##0.00")

 

[Alaa mg]

great ! how can also add to textbox3 for price, please?

 

[DanteAmor]

Replace ComboBox1_Change code for this:

Private Sub ComboBox1_Change()
    Dim i As Long
    Dim prfix As String
    
    If Me.ComboBox1.ListIndex = -1 Then Exit Sub
    If (Not Me.OptionButton1) * (Not Me.OptionButton2) Then
        MsgBox "Select Option first", vbCritical: Exit Sub
    End If
    With Me.ComboBox1
      prfix = IIf(OptionButton1, OptionButton1.Caption, OptionButton2.Caption)
      Me.TextBox1 = Format$(.List(.ListIndex, 0), "#,##0.00;;@")
      Me.TextBox2 = Format$(.List(.ListIndex, 1), "#,##0.00;;@")
      Me.TextBox3 = prfix & " " & Format$(.List(.ListIndex, 2 + IIf(Me.OptionButton1, 0, 1)), "#,##0.00;;@")
      Me.TextBox4 = prfix & " " & Format$(Val(.List(.ListIndex, 1)) * Val(.List(.ListIndex, 2 + IIf(Me.OptionButton1, 0, 1))), "#,##0.00")
    End With
End Sub

 

[Alaa mg]

great assistance !
many thanks

 

[DanteAmor]

I'm glad to help you. Thanks for the feedback.