Print worksheets to single PDF based on a list of worksheet names

[sp2222]

Hi All - I've been searching a long time and can't solve this one.

My Workbook has a Worksheet named "Summary" with a list of various country names in Column A starting at A11. It is a dynamic list, so the countries in this list can change.

My Workbook also has Worksheets for most of the countries. They are named by the country name. There are some countries that appear in the Summary that I do not have a Worksheet for.

I'm trying to create a macro that will save the "Summary" worksheet and all the Country worksheets toa single PDF. If I do not have a worksheet for country, I just want to skip it.

Thanks for any help. I've learned a lot from browsing but this one is proving too advanced for me!

 

[John_w]

Try this macro:

Public Sub Save_Sheets_As_PDF()

    Dim currentSheet As Worksheet
    Dim cell As Range
    Dim ws As Worksheet
    
    With ThisWorkbook.Worksheets("Summary")
        Set currentSheet = ActiveSheet
        .Select
        For Each cell In .Range("A11", .Cells(.Rows.Count, "A").End(xlUp))
            Set ws = Nothing
            On Error Resume Next
            Set ws = ThisWorkbook.Worksheets(cell.Value)
            On Error GoTo 0
            If Not ws Is Nothing Then ws.Select False
        Next
        ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:=ThisWorkbook.Path & "\All Countries.pdf", _
            Quality:=xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:=False
        currentSheet.Select
    End With
    
End Sub

 

[sp2222]

Beautiful, thank you!

 

[sp2222]

Hi @John_w I have one follow up question. Can you update the macro so it will add one more additional sheet to the PDF package? This sheet is called "Introduction" and I would like it to be the first page.

Thanks so much for your assistance.

 

[John_w]

Public Sub Save_Sheets_As_PDF()

    Dim currentSheet As Worksheet
    Dim cell As Range
    Dim ws As Worksheet
    
    ThisWorkbook.Worksheets("Introduction").Select
    With ThisWorkbook.Worksheets("Summary")
        Set currentSheet = ActiveSheet
        .Select False
        For Each cell In .Range("A11", .Cells(.Rows.Count, "A").End(xlUp))
            Set ws = Nothing
            On Error Resume Next
            Set ws = ThisWorkbook.Worksheets(cell.Value)
            On Error GoTo 0
            If Not ws Is Nothing Then ws.Select False
        Next
        ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:=ThisWorkbook.Path & "\All Countries.pdf", _
            Quality:=xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:=False
        currentSheet.Select
    End With
    
End Sub

Note - this and the previous macro create the PDF with sheets in the same order as the workbook, regardless of the order of the sheet names in A11:A<last>. The "Introduction" sheet must be the first sheet in the workbook if you want it to appear as the first page.

 

[sp2222]

Very helpful. Thanks again!