Problem with Shapes in VBA -- Fill is visible?

[shawleigh17]

hello,
I am trying to create a shape that covers a merged cell. This shape should have no fill, so that people can see the contents of the merged cell. Everytime I try to do this, the fill.visible = msoFalse does not seem to work, the white label is still on top of my merged cells. It seemed to work for a little while, but now the label is always filled. I had this problem before, too, when trying to create a label with a text box (the text box would never show), which is why I tried the "no fill" option. Here is the code:

ActiveSheet.Shapes.AddShape(msoShapeRectangle, 1680#, 594#, 120#, 74.25). _
        Select
    Selection.Name = "Upload_Layout"
    ActiveSheet.Shapes("Upload_Layout").Select
    Selection.ShapeRange.Fill.Visible = msoFalse
    Selection.ShapeRange.Fill.Solid
    Selection.ShapeRange.Fill.Transparency = 0#
    Selection.ShapeRange.Line.Weight = 0.75
    Selection.ShapeRange.Line.DashStyle = msoLineSolid
    Selection.ShapeRange.Line.Style = msoLineSingle
    Selection.ShapeRange.Line.Transparency = 0#
    Selection.ShapeRange.Line.Visible = msoTrue
    Selection.ShapeRange.Line.ForeColor.SchemeColor = 64
    Selection.ShapeRange.Line.BackColor.RGB = RGB(255, 255, 255)
    Range("BB25").Select
    ActiveSheet.Shapes("Upload_Layout").Select
    Selection.ShapeRange.Fill.Visible = msoFalse

 

[RoryA]

Is it possible you already have a shape called "Upload_Layout" on the sheet? If so, you would be setting the properties for the wrong shape in your code. Try using:

   Dim shpTemp As Shape
   On Error Resume Next
   ActiveSheet.Shapes("Upload_Layout").Delete
   On Error GoTo 0
   Set shpTemp = ActiveSheet.Shapes.AddShape(msoShapeRectangle, 1680#, 594#, 120#, 74.25)
   With shpTemp
      .Name = "Upload_Layout"
      With .Fill
         .Visible = msoFalse
         .Solid
         .Transparency = 1#
      End With
      With .Line
         .Weight = 0.75
         .DashStyle = msoLineSolid
         .Style = msoLineSingle
         .Transparency = 0#
         .Visible = msoTrue
         .ForeColor.SchemeColor = 64
         .BackColor.RGB = RGB(255, 255, 255)
      End With
   End With

 

[shawleigh17]

Well, I tried that route, and I ended up getting a "Permission Denied" error when trying to name the shape. Any idea why this might be happening?

 

[shawleigh17]

Alright, I somehow fixed the problem, and now it is working perfectly. Thank you very much for your suggestion.

-Shawna