Sending Emails with Signature

[mikeymay]

I have been doing some testing but I'm still struggling to send an email that achieves the following

• Adds the email body to the email to include
  • Carriage returns as per the defined range holding the body text
  • Show the hyperlinks in the defined body text as website addresses e.g. Fourth of July 2022
• Includes the default signature showing the images within the signature, e.g. business logo, FaceBook icon with the associated hyperlink, etc

To date where I can achieve the signature images by using

.Display

straight after the email is created

but then when I then add the email body text by using

.Body = Range("EmailBody") & "<br>" & .Body

the signature is changed to what looks like plain text

Is there a way to retain the signature as the defined defined and the body text to show as defined.


TIA

 

[Georgiboy]

Give the below a try:

Sub test()
    Dim OApp As Object, OMail As Object, signature As String
    
    Set OApp = CreateObject("Outlook.Application")
    
    Set OMail = OApp.CreateItem(0)
    With OMail
        .Display
        DoEvents
    End With
    signature = OMail.HTMLBody
    With OMail
        .to = "jbloggs@somebusiness.com"
        .Subject = "Subject here"
        .HTMLBody = "Body text here" & vbNewLine & signature
        .Send
    End With

    Set OMail = Nothing
    Set OApp = Nothing
End Sub

 

[mikeymay]

Not quite there...

The email body text is not showing the carriage returns.

The email body is some defined text

E.g.
Hi David,

I hope you're keeping well.

Your policy with XXX is due for renewal on blah, blah, blah.

Another paragraph.

Another paragraph

When this is sent in the email it displays as
Hi David, I hope you're keeping well. Your policy with XXX is due for renewal on blah, blah, blah. Another paragraph. Another paragraph

The signature is correct and as required but the body needs to show as the example.


Thanks

 

[Georgiboy]

You will need to format your own HTML text - something like below:

Sub test()
    Dim OApp As Object, OMail As Object, signature
    Dim strbody As String
    
    Set OApp = CreateObject("Outlook.Application")
    
    strbody = "<strong><p style=""font-size:20px"">Hi David," & "<br>" & "<br>" & _
            "I hope you're keeping well." & "<br>" & "<br>" & _
            "Your policy with XXX is due for renewal on blah, blah, blah." & "<br>" & "<br>" & _
            "Another paragraph." & "<br>" & "<br>" & _
            "etc...</p>"

    Set OMail = OApp.CreateItem(0)
    With OMail
        .display
        DoEvents
    End With
    signature = OMail.HTMLBody
    With OMail
        .to = "jbloggs@somebusiness.com"
        .Subject = "Subject here"
        .HTMLBody = strbody & signature
        .Send
    End With

    Set OMail = Nothing
    Set OApp = Nothing
End Sub

 

[mikeymay]

Almost!

The text is now in the correct format using

strBody = Replace(strBody, Chr(10), "<br>")

but the text for the hyperlinks is just text and not hyperlinked.

 

[mikeymay]

Sorry, I only looked at the email when displayed and not sent.....

This now works!!!

Many thanks Georgiboy!

 

[Georgiboy]

Happy to help