Split and copy data from one sheet to another

[sofas]

Hello, I have a datasheet consisting of hundreds of rows. I want to copy it to another sheet, adding 4 empty rows between every 10 rows.
For example, data from A3 to Q10000
A1 to Q2 headings
It is required to copy the first and second rows directly at the top of every 10 rows

 

[Trebor76]

Hi sofas,

It's not super fast (~ 90 seconds for 10,000 records) but this will do the job:

Option Explicit
Sub Macro1()

    Dim i As Long, j As Long, k As Long, x As Long
    Dim lngStep As Long
    Dim wsSrc As Worksheet, wsDestin As Worksheet
    Dim xlnCalcMethod As XlCalculation
    
    With Application
        xlnCalcMethod = .Calculation
        .Calculation = xlCalculationManual
        .EnableEvents = False
        .ScreenUpdating = False
    End With
    
    Set wsSrc = ThisWorkbook.Sheets("Sheet1") '<-Sheet name containing the raw data. Change to suit if necessary.
    Set wsDestin = ThisWorkbook.Sheets("Sheet2") '<-Sheet name containing the raw data. Change to suit if necessary.
    
    j = 3
    k = wsSrc.Range("A:Q").Find("*", SearchOrder:=xlByRows, SearchDirection:=xlPrevious).Row
    lngStep = 10
    
    For i = j To k Step lngStep
        If i = j Then
            wsSrc.Range("A1:Q2").Copy Destination:=wsDestin.Range("A1")
            wsSrc.Range("A" & i & ":Q" & i + lngStep - 1).Copy Destination:=wsDestin.Range("A" & j)
        Else
            x = wsDestin.Range("A:Q").Find("*", SearchOrder:=xlByRows, SearchDirection:=xlPrevious).Row + 5
            wsSrc.Range("A1:Q2").Copy Destination:=wsDestin.Range("A" & x)
            wsSrc.Range("A" & i & ":Q" & i + lngStep - 1).Copy Destination:=wsDestin.Range("A" & x + 2)
        End If
    Next i
    
    With Application
        .Calculation = xlnCalcMethod
        .EnableEvents = True
        .ScreenUpdating = True
    End With

End Sub

Regards,

Robert