Tabs from filtered range

[cuetipper]

I need help please. Cant get this to work.
I am activating the auto filter.
I would like a text box to request the column such as a or b or c
Then for the list of possible filtered entries in that column loop thru each and copy paste results to a new sheet named for that filter.
So in the example below if I choose column c i will get 4 additional sheets label b, c, j, t each with the visible results if filtered by that name.

Order_Id	Appointment_Date	Inspector
9282	05/13/2022 09:00:00	b
9738	06/22/2022 13:30:00	c
9831	06/24/2022 09:00:00	c
9782	06/25/2022 13:30:00	b
9783	06/25/2022 15:30:00	b
9785	06/29/2022 13:30:00	f
9888	06/29/2022 15:30:00	c
NXT9881	06/30/2022 09:00:00	t
NXT9858	07/01/2022 13:30:00	t
NXT9855	07/01/2022 15:30:00	t
NXT9945	07/01/2022 15:30:00	j
NXT9848	07/05/2022 13:30:00	t
NXT9786	07/05/2022 15:30:00	t
NXT9869	07/05/2022 15:30:00	j
NXT9887	07/06/2022 13:30:00	t

 

[DanteAmor]

Note:
For column B the sheet name format will be: "mm-dd-yyyy hh-mm-ss"

Try this:

Sub create_worksheets()
  Dim c As Range, sh As Worksheet, ky As Variant
  Dim col As Variant
  
  Application.ScreenUpdating = False
  
  col = Application.InputBox("Enter column: A, B or C")
  If col = "" Then Exit Sub
  If UCase(col) = "A" Or UCase(col) = "B" Or UCase(col) = "C" Then
    Set sh = ActiveSheet
    With CreateObject("scripting.dictionary")
      For Each c In sh.Range(sh.Cells(2, col), sh.Cells(Rows.Count, col).End(xlUp))
        If c.Value <> "" Then
          .Item(c.Value) = c.Value
        End If
      Next c
      For Each ky In .Keys
        If UCase(col) = "B" Then
          sh.Range("A1").AutoFilter Field:=Columns(col).Column, Operator:=xlFilterValues, Criteria2:=Array(4, Format(ky, "mm/dd/yyyy hh:mm:ss"))
          Sheets.Add(, Sheets(Sheets.Count)).Name = Format(ky, "mm-dd-yyyy hh-mm-ss")
        Else
          sh.Range("A1").AutoFilter Columns(col).Column, ky
          Sheets.Add(, Sheets(Sheets.Count)).Name = ky
        End If
        sh.AutoFilter.Range.EntireRow.Copy Range("A1")
      Next ky
    End With
    sh.Select
    sh.ShowAllData
  End If

  Application.ScreenUpdating = True
End Sub

-----------------
NOTE XL2BB:
For the future, it would help greatly if you could give us the sample data in a form that we can copy to test with.
MrExcel has a tool called “XL2BB” that lets you post samples of your data that will allow us to copy/paste it to our Excel spreadsheets, so we can work with the same copy of data that you are. Instructions on using this tool can be found here: XL2BB Add-in
Note that there is also a "Test Here” forum on this board. This is a place where you can test using this tool (or any other posting techniques that you want to test) before trying to use those tools in your actual posts.