Uppercase To Cell

[data808]

I am using this code for column C. I would like to also apply it to column H. Does anyone know how to do that?

'auto capitalization for all letters in the cell
If Intersect(Target, Range("C:C")) Is Nothing Then Exit Sub
Application.EnableEvents = False
Target.Value = UCase(Target.Value)
Application.EnableEvents = True

I tried a bunch of changes to the code but could not get it to work. Thank you.

 

[Scott Huish]

Private Sub Worksheet_Change(ByVal Target As Range)
Dim c As Range, d As Range, e As Range
Set d = Intersect(Range("C:C"), Target)
Set e = Intersect(Range("H:H"), Target)
If Not d Is Nothing Then
    Application.EnableEvents = False
        For Each c In d
            c = UCase(c)
        Next
    Application.EnableEvents = True
End If

If Not e Is Nothing Then
    Application.EnableEvents = False
        For Each c In e
            c = UCase(c)
        Next
    Application.EnableEvents = True
End If
End Sub

 

[data808]

Private Sub Worksheet_Change(ByVal Target As Range)
Dim c As Range, d As Range, e As Range
Set d = Intersect(Range("C:C"), Target)
Set e = Intersect(Range("H:H"), Target)
If Not d Is Nothing Then
    Application.EnableEvents = False
        For Each c In d
            c = UCase(c)
        Next
    Application.EnableEvents = True
End If

If Not e Is Nothing Then
    Application.EnableEvents = False
        For Each c In e
            c = UCase(c)
        Next
    Application.EnableEvents = True
End If
End Sub

Working great. Thank you very much!

 

[Peter_SSs]

If you want, you could combine into a single range/loop

Private Sub Worksheet_Change(ByVal Target As Range)
  Dim Changed As Range, c As Range
 
  Set Changed = Intersect(Target, Union(Columns("C"), Columns("H")))
  If Not Changed Is Nothing Then
    Application.EnableEvents = False
      For Each c In Changed
        c.Value = UCase(c.Value)
      Next c
    Application.EnableEvents = True
  End If
End Sub

 

[data808]

Private Sub Worksheet_Change(ByVal Target As Range)
Dim c As Range, d As Range, e As Range
Set d = Intersect(Range("C:C"), Target)
Set e = Intersect(Range("H:H"), Target)
If Not d Is Nothing Then
    Application.EnableEvents = False
        For Each c In d
            c = UCase(c)
        Next
    Application.EnableEvents = True
End If

If Not e Is Nothing Then
    Application.EnableEvents = False
        For Each c In e
            c = UCase(c)
        Next
    Application.EnableEvents = True
End If
End Sub

If you want, you could combine into a single range/loop

Private Sub Worksheet_Change(ByVal Target As Range)
  Dim Changed As Range, c As Range
 
  Set Changed = Intersect(Target, Union(Columns("C"), Columns("H")))
  If Not Changed Is Nothing Then
    Application.EnableEvents = False
      For Each c In Changed
        c.Value = UCase(c.Value)
      Next c
    Application.EnableEvents = True
  End If
End Sub

Thanks for the suggestion. I will try it out.