Usefulness of class modules

[tiredofit]

I have been going through classes and wondered if there's any point to it.

The following example is taken from the Mr. Excel Book, VBA And Macros For Microsoft Excel.

This is in module1:

Sub EmpPayOverTime()

Dim Employee As New clsEmployee

With Employee

    .EmpName = "Joe Bloggs"
    .EmpRate = 100
    .EmpWeeklyHrs = 45
    MsgBox .EmpName & Chr(10) & Chr(9) & _
    "Normal Hours: " & .EmpNormalHrs & Chr(10) & Chr(9) & _
    "OverTime Hours: " & .EmpOverTimeHrs & Chr(10) & Chr(9) & _
    "Weekly Pay : $" & .EmpWeeklyPay

End With

End Sub

This is in the class, clsEmployee:

Public EmpName As String
Public EmpRate As Double

Private NormalHrs As Double
Private OverHrs As Double

Property Let EmpWeeklyHrs(Hrs As Double)

NormalHrs = WorksheetFunction.Min(35, Hrs)
OverHrs = WorksheetFunction.Max(0, Hrs - 35)

End Property

Property Get EmpWeeklyHrs() As Double

EmpWeeklyHrs = NormalHrs + OverHrs

End Property

Property Get EmpNormalHrs() As Double

EmpNormalHrs = NormalHrs

End Property

Property Get EmpOverTimeHrs() As Double

EmpOverTimeHrs = OverHrs

End Property

Public Function EmpWeeklyPay() As Double

EmpWeeklyPay = (EmpNormalHrs * EmpRate) + (EmpOverTimeHrs * EmpRate * 2)

End Function

[ASIDE: There's a slight quirk here in that if I step into the module, when I get to the Function EmpWeeklyPay, it jumps to the Property Get EmpOverTimeHrs first. I expected it to read from left to right and so should go to the Property EmpNormalHrs first].

My main question is, what's the diference if I did this?

Put this in module2:

Sub EmpPayOverTimeChanged()

Dim Employee As New clsEmployeechanged

With Employee

    .EmpName = "Joe Bloggs"
    .EmpRate = 100
    .EmpWeeklyHrs = 45
    
    MsgBox .EmpName & Chr(10) & Chr(9) & _
    "Normal Hours: " & .NormalHrs & Chr(10) & Chr(9) & _
    "OverTime Hours: " & .OverHrs & Chr(10) & Chr(9) & _
    "Weekly Pay : $" & .EmpWeeklyPay

End With

End Sub

This is in a new class, clsEmployeechanged:

Public EmpName As String
Public EmpRate As Double

Public NormalHrs As Double
Public OverHrs As Double

Property Let EmpWeeklyHrs(Hrs As Double)

NormalHrs = WorksheetFunction.Min(35, Hrs)
OverHrs = WorksheetFunction.Max(0, Hrs - 35)

End Property

Property Get EmpWeeklyHrs() As Double

EmpWeeklyHrs = NormalHrs + OverHrs

End Property

Public Function EmpWeeklyPay() As Double

EmpWeeklyPay = (NormalHrs * EmpRate) + (OverHrs * EmpRate * 2)

End Function

It seems it does the same thing by simply changing the variables NormalHrs and OverHrs from Private to Public.

 

[Kyle123]

In your example, nothing; there's no tangible difference; it's more convention than anything else. Generally however, you want your classes to be self contained (or group of classes to be self contained) and you'd want to limit the access outside procedures have as well as controlling how the data is returned.

Getting and Letting/Setting allow you to process inputs and outputs to give you better control over your classes, you can be sure that all the private variables are sanitised and in a format that your code expects - you can't do this with public variables, outside procedures could set them to be whatever they like; this would mean you'd have to check the value in the class each and every time you use it.

 

[tiredofit]

In your example, nothing; there's no tangible difference; it's more convention than anything else. Generally however, you want your classes to be self contained (or group of classes to be self contained) and you'd want to limit the access outside procedures have as well as controlling how the data is returned.

Getting and Letting/Setting allow you to process inputs and outputs to give you better control over your classes, you can be sure that all the private variables are sanitised and in a format that your code expects - you can't do this with public variables, outside procedures could set them to be whatever they like; this would mean you'd have to check the value in the class each and every time you use it.

Thanks for your reply.

Do have a couple of related question on classes.

Question 1:

This is in a module:

Sub clsStudentRun()

Dim iStudent As clsStudent
Set iStudent = New clsStudent

iStudent.Name = "Peter"

iStudent.Marks = 45

MsgBox iStudent.Name & " has got " & iStudent.Marks & " percent marks with a Grade " & iStudent.Grade

End Sub

This is in clsStudent:

Private strStuName As String
Private dblStuMarks As Double

Public Property Let Name(strN As String)

strStuName = strN

End Property

Public Property Get Name() As String

Name = strStuName

End Property

Public Property Let Marks(iMarks As Double)

dblStuMarks = (iMarks / 80) * 100

End Property

Public Property Get Marks() As Double

Marks = dblStuMarks

End Property

Public Function Grade() As String

Dim strGrade As String

If dblStuMarks >= 80 Then

strGrade = "A"

ElseIf dblStuMarks >= 60 Then

strGrade = "B"

ElseIf dblStuMarks >= 40 Then

strGrade = "C"

Else

strGrade = "Fail"

End If

Grade = strGrade

End Function

I noticed if I changed Public Function Grade to Public Propoerty Get Grade, it still works, so what's the difference?

Question 2:

This is in a module:

Sub clsRectangleRun()

Dim l As Double
Dim w As Double

Dim rect As New clsRectangle

l = InputBox("Enter Length of rectangle")
w = InputBox("Enter Width of rectangle")

rect.Area(l, w) = l * w

a = rect.Area(l, w)

MsgBox "Area of Rectangle with length " & l & ", width " & w & ", is " & a

End Sub

This is in clsRectangle:

Private dblA As Double

Public Property Let Area(lngth As Double, wdth As Double, ar As Double)

dblA = ar

MsgBox "Arguments received - lngth: " & lngth & ", wdth: " & wdth & ", ar: " & ar

End Property

Public Property Get Area(lngth As Double, wdth As Double) As Double

Area = dblA

End Property

What puzzles me in the second question is that stepping into the module, it asks the user for the length and width and as soon as they are entered, this line is reached:

rect.Area(l, w) = l * w

it then jumps into the class and immediately the variable ar is assigned the value of l * w.

How does it do that?

Thanks again

 

[Kyle123]

The last argument of a property with multiple arguments is passed after the equals sign - though it's a bit confusing at first (not to mention rarely useful) - keep your properties to one parameter

Though if it were me, I'd probably have separate properties for length and width, then a method/read only property to return the area.

 

[tiredofit]

The last argument of a property with multiple arguments is passed after the equals sign - though it's a bit confusing at first (not to mention rarely useful) - keep your properties to one parameter

Though if it were me, I'd probably have separate properties for length and width, then a method/read only property to return the area.

Thanks, I do admit it looked weird, though in my defence, it wasn't written by me!

Any ideas about my first question, ie difference between using method v property?