VBA Code to Delete 4 Cells

[CXOasis]

Hey i am new here and fairly new to excel, I have a problem with my file and was wondering if anyone could help me with some code. I have 1 column (A) and in this column there is about 50K prices. What i am trying to achieve is to clear the contents of 4 cells at a time - So for example the first price is in A2 i need to clear the 4 cells below, then leave the price in A7 then move on to clear the next 4 cells and so on until it reaches the bottom of the column. So it clears 4 cells at a time and leaves one value. Thanks

 

[My Aswer Is This]

Your subject title says delete 4 cells But then you say:
is to clear the contents of 4 cells

Clear and delete are not the same.
So which is it clear or delete.

 

[CXOasis]

Sorry i need to clear them , Not delete , Many thanks for your reply

 

[MARK858]

Maybe something like the code below. Test on a copy of your data

Sub Clear4Cells()

    Dim LastRow As Long, wRng As Range, iRow As Long
    LastRow = Columns(1).Find("*", , xlValues, , xlByRows, xlPrevious).Row

    For iRow = 3 To LastRow Step 5
        If wRng Is Nothing Then
            Set wRng = Cells(iRow, "A").Resize(4)
        Else
            Set wRng = Union(wRng, Cells(iRow, "A").Resize(4))
        End If
    Next iRow

    If Not wRng Is Nothing Then
        wRng.ClearContents
    End If

End Sub

 

[My Aswer Is This]

Assuming You mean clear:
Try this:

Sub Clear_Four_Cells()
'Modified 2/11/2022  4:08:55 PM  EST
Application.ScreenUpdating = False
Dim i As Long
Dim Lastrow As Long
Lastrow = Cells(Rows.Count, "A").End(xlUp).Row

For i = 3 To Lastrow Step 8
    Cells(i, 1).Resize(4).Clear
Next
Application.ScreenUpdating = True
End Sub

 

[MARK858]

So it clears 4 cells at a time and leaves one value

Step 8 will leave four values

 

[CXOasis]

Hey Guys, thank you very much it worked perfectly !

 

[My Aswer Is This]

Hey Guys, thank you very much it worked perfectly !

Glad I was able to help you.
Come back here to Mr. Excel next time you need additional assistance.
I see I read your post wrong