VBA code to place default signature in excel sheet

[YingFa]

Hello,

Is it possible to add a default excel signature with VBA? I would like to add a default signature (maybe excel asking to enter the password) when pressing Button1 to an excel sheet. This sheet will be later on be converted to a pdf file using VBA.

Thank you.

 

[Yongle]

Sub InsertSignature()
    Dim pic As String, cel As Range, shp As Shape, msg As String
    If InputBox("Signature Password", "Enter Password") = "PassWord123" Then
        pic = "C:\folder\subfolder\DefaultSignature.jpg"
        Set cel = Range("A30")
        On Error Resume Next
        Set shp = ActiveSheet.Shapes.AddPicture(pic, msoFalse, msoCTrue, cel.Left, cel.Top, 150, 50)
        If Err.Number <> 0 Then msg = "Signature plate stolen"
    Else
        msg = "Signature declined - incorrect password"
    End If
On Error GoTo 0
If msg <> "" Then MsgBox msg, vbExclamation, "oops"
End Sub

 

[YingFa]

Hi, thank you for your reply on this. I think I missed your message before, but now I just tried the code you shared and it works. I was wondering, can the pic be deleted? This because I have a code that fills an excel sheet every time a new entry is created. When the entry is closed, the picture will need to be placed on the excel, but the form needs to be clear out for the next entry. Is this possible?

 

[Yongle]

The easiest way is to name the picture in the original procedure

Sub InsertSignature()
    Dim pic As String, cel As Range, shp As Shape, msg As String    
    If InputBox("Signature Password", "Enter Password") = "PassWord123" Then
        pic = "C:\folder\subfolder\DefaultSignature.jpg"
        Set cel = Range("A30")
        On Error Resume Next
        Set shp = ActiveSheet.Shapes.AddPicture(pic, msoFalse, msoCTrue, cel.Left, cel.Top, 150, 50)
        shp.Name = "SignaturePlate"
        If Err.Number <> 0 Then msg = "Signature plate stolen"
    Else
        msg = "Signature declined - incorrect password"
    End If
On Error GoTo 0
If msg <> "" Then MsgBox msg, vbExclamation, "oops"
End Sub

so that it can be deleted like this

Sub RemoveSignature()
    On Error Resume Next
    ActiveSheet.Shapes("SignaturePlate").Delete
    On Error GoTo 0
End Sub