Sub CreateEmails()
Application.ScreenUpdating = False
Dim OutApp As Object, OutMail As Object, rng As Range, v As Variant, desWS As Worksheet
Set desWS = Sheets("EMAIL FORMAT")
v = Sheets("Sheet1").Range("A2", Sheets("Sheet1").Range("A" & Rows.Count).End(xlUp)).Resize(, 16).Value
Set OutApp = CreateObject("Outlook.Application")
For i = LBound(v) To UBound(v)
With desWS
.Range("A3") = v(i, 16) & " " & v(i, 15) & " DETAILS"
.Range("B6") = v(i, 3)
.Range("B8:B16") = WorksheetFunction.Transpose(Array(v(i, 2), v(i, 1), v(i, 4), v(i, 6), v(i, 8), v(i, 9), v(i, 7), v(i, 5), v(i, 10)))
.Range("B19") = v(i, 11)
.Range("B24:B26") = WorksheetFunction.Transpose(Array(v(i, 12), v(i, 13), v(i, 14)))
End With
Set rng = desWS.Range("A1:B26")
Set OutMail = OutApp.CreateItem(0)
With OutMail
.To = v(i, 10)
.Subject = desWS.Range("A3")
.HTMLBody = RangetoHTML(rng)
.Display 'Change 'Display' to 'Send' to send the emails automatically without seeing them first.
End With
Next i
Application.ScreenUpdating = True
End Sub
Function RangetoHTML(rng As Range)
Dim fso As Object
Dim ts As Object
Dim TempFile As String
Dim TempWB As Workbook
TempFile = Environ$("temp") & "\" & Format(Now, "dd-mm-yy h-mm-ss") & ".htm"
rng.Copy
Set TempWB = Workbooks.Add(1)
With TempWB.Sheets(1)
.Cells(1).PasteSpecial Paste:=8
.Cells(1).PasteSpecial xlPasteValues, , False, False
.Cells(1).PasteSpecial xlPasteFormats, , False, False
.Cells(1).Select
Application.CutCopyMode = False
On Error Resume Next
.DrawingObjects.Visible = True
.DrawingObjects.Delete
On Error GoTo 0
End With
With TempWB.PublishObjects.Add( _
SourceType:=xlSourceRange, _
Filename:=TempFile, _
Sheet:=TempWB.Sheets(1).Name, _
Source:=TempWB.Sheets(1).UsedRange.Address, _
HtmlType:=xlHtmlStatic)
.Publish (True)
End With
Set fso = CreateObject("Scripting.FileSystemObject")
Set ts = fso.GetFile(TempFile).OpenAsTextStream(1, -2)
RangetoHTML = ts.readall
ts.Close
RangetoHTML = Replace(RangetoHTML, "align=center x:publishsource=", "align=left x:publishsource=")
TempWB.Close savechanges:=False
Kill TempFile
Set ts = Nothing
Set fso = Nothing
Set TempWB = Nothing
End Function