What is wrong my formula?

[azizrasul]

Trying to extract a date in any part of a cell. However I can't get the following formula to work.

=IFERROR(DATEVALUE(LEFT(RIGHT(A2,LEN(A2)-FIND("/",A2)-3))),10)),"")

 

[Joe4]

it comes up with an error "That function isn't valid". It highlights FILTER.

You have listed three different Office Versions that you are using (365, 2019, and 2016).
Which one are you using here, exactly?

The FILTER function is available in 365 and 2019 but not 2016.
See: FILTER function - Microsoft Support

 

[Scott Huish]

What about:
=IFERROR(LOOKUP(10^10,--TRIM(MID(" "&A1,SEARCH("/*/","0"&A1)-2,ROW(INDIRECT("6:10"))))),"")

 

[Peter_SSs]

If you are not using 365 then a non-volatile option might be

24 02 02.xlsm
	A	B
1
2	Financial Statements dated 31/12/2018	31/12/2018
3	Deposits on 10/5/2018 were 25 million	10/05/2018
4	I was born on 2/2/1958	2/02/1958
5	When were you born?
6	You can come and join us on 01/01/2021 for training	1/01/2021
7	2/2/1999 is Tom's DoB	2/02/1999
8	Deposits on 10/5/18 were 25 million	10/05/2018
Extract Date

Cell Formulas
Range	Formula
B2:B8	B2	=IFERROR(--TRIM(MID(A2,MAX(FIND("/",A2)-2,1),FIND(" ",A2&" ",FIND("/",A2))-FIND("/",A2)+2)),"")

 

[azizrasul]

I'm using 2016 version. Both

=IFERROR(LOOKUP(10^10,--TRIM(MID(" "&A2,SEARCH("/*/","0"&A2)-2,ROW(INDIRECT("6:10"))))),"")
=IFERROR(--TRIM(MID(A2,MAX(FIND("/",A2)-2,1),FIND(" ",A2&" ",FIND("/",A2))-FIND("/",A2)+2)),"")

worked. Many thanks all.

 

[Peter_SSs]

Glad you have something that is working.
Not sure how big your data is but if very large then using the volatile function INDIRECT could slow your sheet's performance.

I'm using 2016 version. Both

In future, if you are still going to keep three versions in your profile, please specify in post 1 of a thread which one or ones of those three versions the solution has to work in. Then helpers won't be wasting time developing solutions for the wrong version(s).

 

[azizrasul]

Will do.