Writing large ranges to multiple cells

[krshnn]

I need an alternative to below way of writing codes
Range("A1").value = "S.No"
Range("B1").value = "Bill No"
Range("c1").value = "Shipping bill no"
Range("D1").value = "code"
Range("E1").value = "Processing partner"
Range("f1").value = "FOB value"
and so on till Range("Z1").

At times, my requirement might be in A1.value to A20.value sort of fashion (i.e., vertical manner rather than horizontal manner)

So basically the question is there an easier an way to write the above lines of code without including range/cell address each time.
I'm okay with entering contiguous cell range once.
Request you to provide answer for both multiple vertical range.value and horizontal range.value scenarios.

 

[My Aswer Is This]

Try something like this:
One for Horizontal in row 1
Modify array values

Sub Using_Arrray_Horizonal()
'Modified 11/1/2022  1:12:11 PM  EST
Application.ScreenUpdating = False
Dim i As Long
Dim Del As Variant
Dim s As Long
Del = Array("Alpha", "Bravo", "Charlie", "Delta", "Echo")
s = UBound(Del)

For i = 0 To s
    Cells(1, i + 1).Value = Del(i)
Next
Application.ScreenUpdating = True

End Sub

One for Vertical in Column 1
Modify array values:

Sub Using_Arrray_Vertical()
'Modified 11/1/2022  1:12:11 PM  EST
Application.ScreenUpdating = False
Dim i As Long
Dim Del As Variant
Dim s As Long
Del = Array("Alpha", "Bravo", "Charlie", "Delta", "Echo")
s = UBound(Del)

For i = 0 To s
    Cells(i + 1, 1).Value = Del(i)
Next
Application.ScreenUpdating = False

End Sub

 

[My Aswer Is This]

Try this For Row(1)

Sub Using_Arrray_Horizonal()
'Modified 11/1/2022  1:12:11 PM  EST
Application.ScreenUpdating = False
Dim i As Long
Dim Del As Variant
Dim s As Long
Del = Array("Alpha", "Bravo", "Charlie", "Delta", "Echo")
s = UBound(Del)

For i = 0 To s
    Cells(1, i + 1).Value = Del(i)
Next
Application.ScreenUpdating = True
MsgBox "Horizontal"

End Sub

Try this for column 1

Sub Using_Arrray_Vertical()
'Modified 11/1/2022  1:12:11 PM  EST
Application.ScreenUpdating = False
Dim i As Long
Dim Del As Variant
Dim s As Long
Del = Array("Alpha", "Bravo", "Charlie", "Delta", "Echo")
s = UBound(Del)

For i = 0 To s
    Cells(i + 1, 1).Value = Del(i)
Next
Application.ScreenUpdating = True
MsgBox "Vertical"
End Sub

 

[Fluff]

Another option is
For horizontal

Sub krshnn()
   Dim Ary As Variant
   
   Ary = Array("S.No", "Bill No", "Shipping bill no", "code", "Processing partner", "FOB value")
   Range("A1").Resize(, UBound(Ary) + 1).Value = Ary
End Sub

and Vertical

Sub krshnn()
   Dim Ary As Variant
   
   Ary = Array("S.No", "Bill No", "Shipping bill no", "code", "Processing partner", "FOB value")
   Range("A1").Resize(UBound(Ary) + 1).Value = Application.Transpose(Ary)
End Sub