VBA to copy Active Workbook to a new Workbook

[AHilgers]

I want to copy the active workbook to a new workbook. I have code now that copies the active sheet, but I want all sheets.

Sub Mail_ActiveSheet()
'Working in 2000-2007
Dim FileExtStr As String
Dim FileFormatNum As Long
Dim Sourcewb As Workbook
Dim Destwb As Workbook
Dim TempFilePath As String
Dim TempFileName As String
Dim OutApp As Object
Dim OutMail As Object
With Application
.ScreenUpdating = False
.EnableEvents = False
End With
Set Sourcewb = ActiveWorkbook
'Copy the workbook to a new workbook

ActiveSheet.Copy
Set Destwb = ActiveWorkbook

 

[timorrill]

Do you mean that you want to save a copy of the active workbook, so that you can attach it to an email?

 

[AHilgers]

Yes, the rest of the code attaches it to the email and then deletes the temporary file that is created.

 

[timorrill]

Try this:

ActiveWorkbook.SaveCopyAs "C:\CopyOfMyWorkbook.xls"

This code will save a copy of your current workbook to the location specified. You can then attach this file to the email, send the email, delete the file, etc...

 

[AHilgers]

Instead of doing a FileSaveAs, is there any way to use a Copy command? I think that would work better with the rest of my code.

 

[timorrill]

Can you post the rest of your code? It seems like SaveCopyAs should be quite easy to use with code to add attachments to an Outlook email.

 

[AHilgers]

Sub Mail_ActiveSheet()
'Working in 2000-2007
    Dim FileExtStr As String
    Dim FileFormatNum As Long
    Dim Sourcewb As Workbook
    Dim Destwb As Workbook
    Dim TempFilePath As String
    Dim TempFileName As String
    Dim OutApp As Object
    Dim OutMail As Object
    With Application
        .ScreenUpdating = False
        .EnableEvents = False
    End With
    Set Sourcewb = ActiveWorkbook
    'Copy the sheet to a new workbook
[COLOR=red]    ActiveSheet.Copy
[/COLOR]    Set Destwb = ActiveWorkbook
    'Determine the Excel version and file extension/format
    With Destwb
        If Val(Application.Version) < 12 Then
            'You use Excel 2000-2003
            FileExtStr = ".xls": FileFormatNum = -4143
        Else
            'You use Excel 2007, we exit the sub when your answer is
            'NO in the security dialog that you only see  when you copy
            'an sheet from a xlsm file with macro's disabled.
            If Sourcewb.Name = .Name Then
                With Application
                    .ScreenUpdating = True
                    .EnableEvents = True
                End With
                MsgBox "Your answer is NO in the security dialog"
                Exit Sub
            Else
                Select Case Sourcewb.FileFormat
                Case 51: FileExtStr = ".xlsx": FileFormatNum = 51
                Case 52:
                    If .HasVBProject Then
                        FileExtStr = ".xlsm": FileFormatNum = 52
                    Else
                        FileExtStr = ".xlsx": FileFormatNum = 51
                    End If
                Case 56: FileExtStr = ".xls": FileFormatNum = 56
                Case Else: FileExtStr = ".xlsb": FileFormatNum = 50
                End Select
            End If
        End If
    End With
    '    'Change all cells in the worksheet to values if you want
    '    With Destwb.Sheets(1).UsedRange
    '        .Cells.Copy
    '        .Cells.PasteSpecial xlPasteValues
    '        .Cells(1).Select
    '    End With
    '    Application.CutCopyMode = False
    'Save the new workbook/Mail it/Delete it
    TempFilePath = "H:\"
    TempFileName = "Part of " & Sourcewb.Name & " " _
                 & Format(Now, "dd-mmm-yy h-mm-ss")
    Set OutApp = CreateObject("Outlook.Application")
    OutApp.Session.Logon
    Set OutMail = OutApp.CreateItem(0)
    With Destwb
        .SaveAs TempFilePath & TempFileName & FileExtStr, _
                FileFormat:=FileFormatNum
        On Error Resume Next
'Enter the recipient of the email
        With OutMail
            .To = "Joyce"
            .CC = ""
            .BCC = ""
            .Subject = "Funds Availability Hold"
            .Body = ""
            .Attachments.Add Destwb.FullName
            'You can add other files also like this
            '.Attachments.Add ("C:\test.txt")
            .Send   'or use .Display
        End With
        On Error GoTo 0
        .Close SaveChanges:=False
    End With
    'Delete the file you have send
    Kill TempFilePath & TempFileName & FileExtStr
    Set OutMail = Nothing
    Set OutApp = Nothing
    With Application
        .ScreenUpdating = True
        .EnableEvents = True
    End With
End Sub

This is my original code. My problem is the code in red. It is only copying the active sheet and emailing that one. I want to email all the sheets.

Thanks!

 

[timorrill]

Would it not suffice to do something like this?

Dim strAttachmentFilename as String
strAttachementFilename = "C:\MyAttachment.xls"
ActiveWorkbook.SaveCopyAs strAttachmentFilename
...
Attachments.Add strAttachmentFilename
...
Kill strAttachmentFilename

What is it that you don't like about using this approach?

 

[Domski]

ActiveWorkbook.Sheets.Copy

Will copy all sheets to a new workbook.

Dom

 

[AHilgers]

This worked perfectly.

Thanks so much.