Macro to delete emails from specific senders is not working

[musicgold]

Hi,

I use Outlook 2010 and am trying to create a macro to delete emails from specific senders. See my code below.
For some reason the code doesn't loop through all emails in my inbox; it just go through a first few emails. Why is it happening?

Dim oloutlook As Outlook.Application
Dim ns As Outlook.NameSpace
Dim itm As Outlook.Items
Dim Myitem As MailItem
Dim counter As Integer
Dim olTrash As Object
Dim msg As String

On Error Resume Next

Set oloutlook = CreateObject("Outlook.Application")
Set ns = oloutlook.GetNamespace("MAPI")
Set itm = ns.GetDefaultFolder(olFolderInbox)
Set olTrash = ns.GetDefaultFolder(olFolderDeletedItems)

MsgBox itm.Items.Count
counter = 0

For Each Myitem In itm.Items
        
   Select Case UCase(Myitem.SenderName)
       
   Case UCase("Adam Berry")
         Myitem.Move olTrash
         counter = counter + 1
        
   Case UCase("John Nash")
         Myitem.Move olTrash
         counter = counter + 1
         
   End Select
 
 Next

Set oloutlook = Nothing
Set ns = Nothing
Set itm = Nothing

MsgBox "deleted " & counter

 

[hippiehacker]

its your looping through the mails whenever a mail gets deleted the next one will be skipped

you have to loop backwards through the mails like

<code>For i = Inbox.Items.Count To 1 Step -1 'Iterates from the end backwards
    Set InboxMsg = Inbox.Items(i)</code></pre>

 

[phairplay]

Guys

how would see work look compiled together as I would really like to use this


cheers

 

[hippiehacker]

the for loop combined

For i = Inbox.Items.Count To 1 Step -1 'Iterates from the end backwards
    Set InboxMsg = Inbox.Items(i)
        
   Select Case UCase(InboxMsg.SenderName)
       
   Case UCase("Adam Berry")
         Myitem.Move olTrash
         counter = counter + 1
        
   Case UCase("John Nash")
         Myitem.Move olTrash
         counter = counter + 1
         
   End Select
 
 Next

 

[phairplay]

many thanks

 

[Mechixx]

If anyone is looking to use this, Ive compiled it into a complete working macro as it took some adjustments to get it to work, here's the full code:

Dim oloutlook As Outlook.Application
Dim ns As Outlook.NameSpace
Dim itm As Object
Dim Myitem As MailItem
Dim counter As Integer
Dim MailNumber As Long
Dim i As Long
Dim olTrash As Object

On Error Resume Next

Set oloutlook = CreateObject("Outlook.Application")
Set ns = oloutlook.GetNamespace("MAPI")
Set itm = ns.GetDefaultFolder(olFolderInbox)
Set olTrash = ns.GetDefaultFolder(olFolderDeletedItems)

MailNumber = itm.Items.count
counter = 0


For i = itm.Items.count To 1 Step -1 'Iterates from the end backwards
    Set Myitem = itm.Items(i)
        
   Select Case UCase(Myitem.SenderName)
       
   Case UCase("Adam Berry")
         Myitem.Move olTrash
         counter = counter + 1
         
   Case UCase("John Nash")
         Myitem.Move olTrash
         counter = counter + 1
   End Select
 
 Next
 

Set oloutlook = Nothing
Set ns = Nothing
Set itm = Nothing

MsgBox "Deleted " & counter & " of " & MailNumber