A much simpler alternative to the FindWindow API for retrieving the HWND of UserForms

[Jaafar Tribak]

Hi all,

Just wanted to share this little known API function for those who need to retrieve the Window handle (hwnd) of a userform.

As you all know, the standard approach is to use the FindWindow API but this has two awkward issues :

[COLOR=#000000]Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long[/COLOR]

1- The first argument of the FindWindow API expects the UserForm Window Class name . This adds complexity to the code because there are two different Class names (ThunderXFrame vs ThunderDFrame) depending on the excel application version ...So an extra check is needed.

2 - The FindWindow function expects the Form's Caption to be passed in its second argument . This too, may cause a problem if there happens to be more than one instance of a userform loaded @ the same time with the same Caption.

Fortunately, there is this handy API that I came accross recently called IUnknown_GetWindow which dispenses us from the two problems mentioned above and is very simple . This API is exported by its ordinal number by the shlwapi library.

The API has two parameters : An IN parameter that receives a pointer to userform object and an OUT parameter that returns a pointer to the hwnd.

https://msdn.microsoft.com/en-us/library/windows/desktop/bb773814(v=vs.85).aspx

Usage Example:

Option Explicit

#If Win64 Then
    Private Declare PtrSafe Function IUnknown_GetWindow Lib _
    "shlwapi" Alias "#172" (ByVal pIUnk As IUnknown, ByVal hwnd As LongPtr) As Long
#Else
    Private Declare Function IUnknown_GetWindow Lib _
    "shlwapi" Alias "#172" (ByVal pIUnk As IUnknown, ByVal hwnd As Long) As Long
#End If
 
Public Function GetUserformHwnd(ByVal ufmTarget As MSForms.UserForm) As Long
     IUnknown_GetWindow ufmTarget, VarPtr(GetUserformHwnd)
End Function


Sub Test()
     
    Dim ufm1 As UserForm1
    Dim ufm2 As UserForm1
    Dim lngUserform As Long
     
    Set ufm1 = New UserForm1
    Set ufm2 = New UserForm1
     
    For lngUserform = 0 To UserForms.Count - 1
        Debug.Print GetUserformHwnd(UserForms(lngUserform))
    Next lngUserform
     
End Sub

One would expect to use this neat API to get the much needed hwnd of a workbook window .. Unfortunately, this is not true. This API function seems to only work with a limted number of COM Interfaces .

 

[John_w]

I came across the solution whilst playing around with pointers, though I don't understand why.

It works if you declare the first parameter of WindowFromAccessibleObject as "ByVal pacc As Object" instead of "ByVal pacc As IAccessible".

Here is the code, including different declarations of WindowFromAccessibleObject if the code is running as 64-bit or as 32-bit.

Option Explicit

Public Const ConstWindowsClass As String = "ThunderDFrame"

[URL=https://www.mrexcel.com/forum/usertag.php?do=list&action=hash&hash=If]#If[/URL]  VBA7 Then
    [URL=https://www.mrexcel.com/forum/usertag.php?do=list&action=hash&hash=If]#If[/URL]  Win64 Then
        Public Declare PtrSafe Function WindowFromAccessibleObject Lib "oleacc" _
            (ByVal pacc As IAccessible, phwnd As LongPtr) As Long
    [URL=https://www.mrexcel.com/forum/usertag.php?do=list&action=hash&hash=Else]#Else[/URL] 
        Public Declare PtrSafe Function WindowFromAccessibleObject Lib "oleacc" _
            (ByVal pacc As Object, phwnd As LongPtr) As Long
    [URL=https://www.mrexcel.com/forum/usertag.php?do=list&action=hash&hash=End]#End[/URL]  If
    Public Declare PtrSafe Function FindWindow Lib "user32" Alias "FindWindowA" _
        (ByVal lpClassName As String, ByVal lpWindowName As String) As LongPtr
[URL=https://www.mrexcel.com/forum/usertag.php?do=list&action=hash&hash=Else]#Else[/URL] 
    Public Declare Function WindowFromAccessibleObject Lib "oleacc" _
        (ByVal pacc As IAccessible, phwnd As Long) As Long
    Public Declare Function FindWindow Lib "user32" Alias "FindWindowA" _
        (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
[URL=https://www.mrexcel.com/forum/usertag.php?do=list&action=hash&hash=End]#End[/URL]  If


[URL=https://www.mrexcel.com/forum/usertag.php?do=list&action=hash&hash=If]#If[/URL]  VBA7 Then
    Private Function GetUserformHwnd(ByVal ufmTarget As MSForms.UserForm) As LongPtr
[URL=https://www.mrexcel.com/forum/usertag.php?do=list&action=hash&hash=Else]#Else[/URL] 
    Private Function GetUserformHwnd(ByVal ufmTarget As MSForms.UserForm) As Long
[URL=https://www.mrexcel.com/forum/usertag.php?do=list&action=hash&hash=End]#End[/URL]  If
        
    WindowFromAccessibleObject ufmTarget, GetUserformHwnd
    
End Function

'Comparing handle returned by WindowFromAccessibleObject and FindWindow - now they are the same value

Sub Test2()
     
    Dim ufm1 As UserForm1
    
    Set ufm1 = New UserForm1
    ufm1.Show vbModeless
    
    Debug.Print "FindWindow ="; FindWindow(ConstWindowsClass, ufm1.Caption)
    Debug.Print "WindowFromAccessibleObject ="; GetUserformHwnd(ufm1)
    
    Unload ufm1
     
End Sub

 

[Jaafar Tribak]

I had already done that before posting this API approach by replacing the pacc arg type with Object and IUknown and they both worked as expected.

I am not sure why it didn't work for you using IAccessible as per the documentation of the WindowFromAccessibleObject API but I'll try asking some COM experts in other forums.