Activate based on Date

[Hawk04]

Hello: I'm trying to activate a command button on an entry form by determining if the year is the year after the current file was created. The purpose is to allow the user to auto-populate data at the beginning of a new golf season. As I am not very familiar with using dates in VBA I have tried a variety of code examples with all giving me errors. My latest attempt is:

Sub Start_Year()

    'Code to determine whether cmdStartYear is enabled
    Dim CurrentYear As Date
    Dim YrCreated As Date
    Dim oWB As Workbook
    
    Set oWB = ActiveWorkbook
    
    CurrentYear = Year(Date)
    
    YrCreated = Format(oWB.DateCreated, "yyyy")

    If CurrentYear = YrCreated + 1 Then
        cmdStartYear.Visible = True
        Else: cmdStartYear.Visible = False
    End If

End Sub

All versions tried result in the failure of my entry form to open and this latest version returns an error message "Object doesn't support this property or method" and I feel stupid that I can't see what is causing this.

Thanks in advance for any advice.

 

[d_boggus]

try

Sub Start_Year()
    'Code to determine whether cmdStartYear is enabled
    Dim CurrentYear As Date
    Dim YrCreated As Date
    Dim oWB As Workbook
 
    Set oWB = ActiveWorkbook
 
    CurrentYear = Year(Date)
 
    YrCreated = Format(oWB.BuiltinDocumentProperties("Creation Date"), "yyyy")
    If CurrentYear = YrCreated + 1 Then
        cmdStartYear.Visible = True
    Else
        cmdStartYear.Visible = False
    End If
End Sub

 

[SillyCat]

Here you go:

Sub Start_Year()

    'Code to determine whether cmdStartYear is enabled
    Dim CurrentYear As Integer
    Dim YrCreated As Integer
    
    Dim oWB As Workbook
    
    Set oWB = ActiveWorkbook
    
    CurrentYear = Format(Date, "yyyy")
    
    YrCreated = Format(oWB.BuiltinDocumentProperties("Creation Date"), "yyyy")
    
    If CurrentYear = YrCreated + 1 Then
        cmdStartYear.Visible = True
        Else: cmdStartYear.Visible = False
    End If

End Sub

 

[AlphaFrog]

Sub Start_Year()

    'Code to determine whether cmdStartYear is enabled
 
    If Year(Date) = CInt(Format(ActiveWorkbook.BuiltinDocumentProperties("Creation Date"), "yyyy")) + 1 Then
        cmdStartYear.Visible = True
    Else
        cmdStartYear.Visible = False
    End If
    
End Sub

 

[Hawk04]

Thanks to all who responded so quickly! I see what I missed and have it working now! You folks are Great!

 

[AlphaFrog]

FYI you don'rt really need the IF statement...

Sub Start_Year()
    
    cmdStartYear.Visible = Year(Date) = CInt(Format(ActiveWorkbook.BuiltinDocumentProperties("Creation Date"), "yyyy")) + 1
    
End Sub

 

[Hawk04]

Thanks AlphaFrog! That really simplifies it!