Add 3 items to combo box list

[Av8tordude]

I have this code that add unique list to my combo box. I would like to know how I can add three items that will show in the first three items in the combo box list

i.e.

Standard 3 item list that will show no matter what
mary
Tom
John

And then the list the code includes below the standard list

Private Sub UpdateList()
Dim Dic As Object: Set Dic = CreateObject("Scripting.Dictionary")
Dim rCell As Range, x, y, z

cbName.Clear
x = Wks.Cells(Rows.Count, "A").End(xlUp).Row

If x > 6 Then
    For Each rCell In Wks.Range("A7:A" & x)
        If Not Dic.Exists(rCell.Value) Then
            Dic.Add rCell.Value, Nothing
        End If
    Next rCell
    cbName.List = Dic.Keys
    
    With cbName
        For x = LBound(.List) To UBound(.List)
            For y = x To UBound(.List)
                If .List(y, 0) < .List(x, 0) Then
                    z = .List(y, 0)
                    .List(y, 0) = .List(x, 0)
                    .List(x, 0) = z
                End If
            Next y
        Next x
    End With
End If
End Sub

 

[Fluff]

What is your current code?

 

[Rick Rothstein]

If you are using an ActiveX ComboBox, then I think this will do what you want...

Sub UpdateList()
  Dim X As Long, Data As Variant, Delimiter
  Delimiter = "|"
  Data = Range("A7", Cells(Rows.Count, "A").End(xlUp))
  With CreateObject("Scripting.Dictionary")
    For X = 1 To UBound(Data)
      .Item(Data(X, 1)) = 1
    Next
    cbName.List = Split(Join(Array("Mary", "Tom", "John"), Delimiter) & Delimiter & Join(.keys, Delimiter), Delimiter)
  End With
End Sub

 

[Av8tordude]

Rick...that did the trick. Thank you guys

 

[Fluff]

I thought you need to sort the values in the combo?

 

[Av8tordude]

Yep...I just added the other part of the code to it...

Private Sub UpdateReason()
Dim X As Long, Data As Variant, Delimiter

Delimiter = "|"
Data = Range("S7:S" & Application.Max(7, Range("A" & Rows.Count).End(xlUp).Row))

With CreateObject("Scripting.Dictionary")
    For X = 1 To UBound(Data)
      .Item(Data(X, 1)) = 1
    Next
    cbReason.List = Split(Join(Array("Good Trade", "Bad Trade", "Confident", "Broke Rules"), Delimiter) & Delimiter & Join(.keys, Delimiter), Delimiter)
End With

With cbReason
    For X = LBound(.List) To UBound(.List)
        For y = X To UBound(.List)
            If .List(y, 0) < .List(X, 0) Then
                z = .List(y, 0)
                .List(y, 0) = .List(X, 0)
                .List(X, 0) = z
            End If
        Next y
    Next X
End With

 

[Rick Rothstein]

Sorry, I missed the part about wanting the list sorted. Here is the subroutine I posted earlier with my method of sorting it before assigning it to the ComboBox...

Private Sub UpdateReason()
    Dim X As Long, Data As Variant, Delimiter As String, Uniques() As String
    
    Delimiter = "|"
    Data = Range("S7:S" & Application.Max(7, Range("A" & Rows.Count).End(xlUp).Row))
    
    With CreateObject("Scripting.Dictionary")
        For X = 1 To UBound(Data)
            .Item(Data(X, 1)) = 1
        Next
        Uniques = Split(Join(Array("Good Trade", "Bad Trade", "Confident", "Broke Rules"), Delimiter) & Delimiter & Join(.Keys, Delimiter), Delimiter)
    End With
    
    With CreateObject("System.Collections.ArrayList")
        For X = 0 To UBound(Uniques)
            .Add Uniques(X)
        Next
        .Sort
        cbReason.List = .ToArray
    End With
End Sub