Add Checkbox with new table row

[vanwooten]

I have a table where the first row contains a checkbox:

I use the following code to add rows to this table:

Set newrow = WS.ListObjects("Trades").ListRows.Add

With newrow
.Range(1) = Date
.Range(3) = "0930"
.Range(5) = "=IFS($J$3=""Eastern"",VLOOKUP([@[Etime Convert]],Sheet1!A$2:B$23,2,TRUE),$J$3=""Central"",VLOOKUP([@[Etime Convert]],Sheet1!C$2:D$23,2,TRUE),$J$3=""Mountain"",VLOOKUP([@[Etime Convert]],Sheet1!E$2:F$23,2,TRUE),$J$3=""Pacific"",VLOOKUP([@[Etime Convert]],Sheet1!G$2:H$23,2,TRUE))"
.Range(6) = WS.Range("I5")
.Range(7) = WS.Range("K5")
.Range(8) = WS.Range("J5")
.Range(9) = 0
.Range(10) = 0
.Range(11) = WS.Range("L7")
.Range(18) = 0
End With

As you can see in the image, I am not getting checkboxes on new rows and I would like to have them with the same formatting and the linked cell moving to the new row. Any Ideas?

 

[John_w]

You don't actually say which column should contain the checkbox and which cell should be the linked cell. Assuming column 2 of the table and the linked cell is the same cell that the checkbox sits in:

    Dim cbShape As Shape
    Dim cb As CheckBox
   
    Set newRow = WS.ListObjects("Trades").ListRows.Add
   
    With newRow
        Set cbShape = WS.Shapes.AddFormControl(xlCheckBox, .Range(2).Left, .Range(2).Top - 1, 15, 15)
        With cbShape
            .Name = "cb_" & newRow.Index
            .TextFrame.Characters.Text = ""
            Set cb = .OLEFormat.Object
        End With
        cb.LinkedCell = .Range(2).Address
        ':
        ':
    End With

Or shorter:

    Dim cb As CheckBox
    Set newRow = WS.ListObjects("Trades").ListRows.Add
   
    With newRow
        Set cb = WS.CheckBoxes.Add(.Range(2).Left, .Range(2).Top - 1, 15, 15)
        With cb
            .Caption = ""
            .LinkedCell = newRow.Range(2).Address
        End With
        ':
        ':
    End With

 

[vanwooten]

Thank you sir!