Adding every other column with criteria

[tycasey17]

I'm trying to add multiple columns based on a code in between the number. I tried doing a =SUMIF but I wasn't figuring out how to adjust it. The reason I have it this way is because I'll order everything together, but it will come in piece by piece. I use three codes: OO - On Order; REC - Received; ISS - Issued. The bold is the end result I would like to have for the tracking I'm planning on doing.

	Coat Status	Coat QTY	Pants Status	Pants QTY	Shirt Status	Shirt QTY	TOTAL OO	TOTAL REC	TOTAL ISS
Doe, John	OO	1	OO	1	REC	1	2	1	0
Doe, Jane	ISS	2	OO	1	REC	2	1	2	2

 

[SanjayGMusafir]

Check this and revert -

Book1
	A	B	C	D	E	F	G	H	I	J	K	L	M
1		Coat Status	Coat QTY	Pants Status	Pants QTY	Shirt Status	Shirt QTY	OO	REC	ISS	TOTAL OO	TOTAL REC	TOTAL ISS
2	Doe, John	OO	1	OO	1	REC	1	2	1	0	2	1	0
3	Doe, Jane	ISS	2	OO	1	REC	2	1	2	2	1	2	2
Sheet1

Cell Formulas
Range	Formula
H2:J3	H2	=IF($B2=H$1,$C2,0)+IF($D2=H$1,$E2,0)+IF($F2=H$1,$G2,0)

 

[Fluff]

Another option

Fluff.xlsm
	A	B	C	D	E	F	G	H	I	J
1		Coat Status	Coat QTY	Pants Status	Pants QTY	Shirt Status	Shirt QTY	TOTAL OO	TOTAL REC	TOTAL ISS
2	Doe, John	OO	1	OO	1	REC	1	2	1	0
3	Doe, Jane	ISS	2	OO	1	REC	2	1	2	2
Sheet5

Cell Formulas
Range	Formula
H2:H3	H2	=SUMIFS(C2:G2,B2:F2,"OO")
I2:I3	I2	=SUMIFS(C2:G2,B2:F2,"rec")
J2:J3	J2	=SUMIFS(C2:G2,B2:F2,"iss")

 

[dreid1011]

Edit: Oops, left the post open and didn't see other solutions.

Perhaps this:

Book1 11-27-2023.xlsx
	A	B	C	D	E	F	G	H	I	J
1		Coat Status	Coat QTY	Pants Status	Pants QTY	Shirt Status	Shirt QTY	TOTAL OO	TOTAL REC	TOTAL ISS
2	Doe, John	OO	1	OO	1	REC	1	2	1	0
3	Doe, Jane	ISS	2	OO	1	REC	2	1	2	2
Sheet4

Cell Formulas
Range	Formula
H2:H3	H2	=SUMPRODUCT(($B2="OO")*$C2+($D2="OO")*$E2+($F2="OO")*$G2)
I2:I3	I2	=SUMPRODUCT(($B2="REC")*$C2+($D2="REC")*$E2+($F2="REC")*$G2)
J2:J3	J2	=SUMPRODUCT(($B2="ISS")*$C2+($D2="ISS")*$E2+($F2="ISS")*$G2)

 

[SanjayGMusafir]

Using @Fluff 's idea I generated Option 2
You can check either Option 1 or Option 2 whichever suits you -

Book2
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P
1		Coat Status	Coat QTY	Pants Status	Pants QTY	Shirt Status	Shirt QTY	OO	REC	ISS	OO	REC	ISS	TOTAL OO	TOTAL REC	TOTAL ISS
2	Doe, John	OO	1	OO	1	REC	1	2	1	0	2	1	0	2	1	0
3	Doe, Jane	ISS	2	OO	1	REC	2	1	2	2	1	2	2	1	2	2
4
5								Option 1			Option 2
6
Sheet1

Cell Formulas
Range	Formula
H2:J3	H2	=IF($B2=H$1,$C2,0)+IF($D2=H$1,$E2,0)+IF($F2=H$1,$G2,0)
K2:M3	K2	=SUMIFS($C2:$G2,$B2:$F2,K$1)

 

[Peter_SSs]

Another SUMIFS option that uses a single formula copied to all cells.

23 11 29.xlsm
	B	C	D	E	F	G	H	I	J
1	Coat Status	Coat QTY	Pants Status	Pants QTY	Shirt Status	Shirt QTY	TOTAL OO	TOTAL REC	TOTAL ISS
2	OO	1	OO	1	REC	1	2	1	0
3	ISS	2	OO	1	REC	2	1	2	2
SUMIFS

Cell Formulas
Range	Formula
H2:J3	H2	=SUMIFS($C2:$G2,$B2:$F2,SUBSTITUTE(H$1,"TOTAL ",""))

 

[tycasey17]

Thank you all for your assistance, each one worked but I ended up using the most simplistic formula.

 

[Fluff]

Glad we could help & thanks for the feedback.