AINSERT

[Xlambda]

AINSERT !! recursive !! array insert, insert any string delimiter "d" between characters of an array "a" with a selectable pace "p" and selectable starting point "i".

=LAMBDA(a,d,p,i,
    LET(ld,LEN(d),k,MAX(p,1),j,MAX(k+1,i),n,MAX(LEN(a)),
       IF(n<(j-1),SUBSTITUTE(TRIM(SUBSTITUTE(a,d," "))," ",d),AINSERT(REPLACE(a,j,,d),d,k,j+2*(k+1)-k-1+ld-1))
    )
)

LAMBDA 6.0.xlsx
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q	R
1	sample		=AINSERT(A2:A4,"-",1,)
2	qwertyuiop98765		q-w-e-r-t-y-u-i-o-p-9-8-7-6-5
3	asdfghjkl123		a-s-d-f-g-h-j-k-l-1-2-3
4	zxcvbnm123456		z-x-c-v-b-n-m-1-2-3-4-5-6
5
6			=AINSERT(A2:A4,"--",,)
7			q--w--e--r--t--y--u--i--o--p--9--8--7--6--5
8			a--s--d--f--g--h--j--k--l--1--2--3
9			z--x--c--v--b--n--m--1--2--3--4--5--6
10				extract values with				ASPLIT					extract only text values with				AFILTER
11			=AINSERT(A2:A4,"-",2,)	=ASPLIT(C12:C14,"-")									=AFILTER(D12#,-1,)
12			qw-er-ty-ui-op-98-76-5	qw	er	ty	ui	op	98	76	5		qw	er	ty	ui	op
13			as-df-gh-jk-l1-23	as	df	gh	jk	l1	23				as	df	gh	jk	l1
14			zx-cv-bn-m1-23-45-6	zx	cv	bn	m1	23	45	6			zx	cv	bn	m1
15
16			=AINSERT(A2:A4,"--",3,)	=ASPLIT(C17#,"--")									extract only numeric values
17			qwe--rty--uio--p98--765	qwe	rty	uio	p98	765					=AFILTER(D12#,1,)
18			asd--fgh--jkl--123	asd	fgh	jkl	123						98	76	5
19			zxc--vbn--m12--345--6	zxc	vbn	m12	345	6					23
20													23	45	6
21			i=5,inserting starts after 4th character
22			=AINSERT(A2:A4,"///",3,5)	=ASPLIT(C23#,"///")
23			qwer///tyu///iop///987///65	qwer	tyu	iop	987	65
24			asdf///ghj///kl1///23	asdf	ghj	kl1	23
25			zxcv///bnm///123///456	zxcv	bnm	123	456
26
AINSERT post

Cell Formulas
Range	Formula
C1,C22:D22,M17,C16:D16,M11,C11:D11,C6	C1	=FORMULATEXT(C2)
C2:C4	C2	=AINSERT(A2:A4,"-",1,)
C7:C9	C7	=AINSERT(A2:A4,"--",,)
C12:C14	C12	=AINSERT(A2:A4,"-",2,)
D12:K14	D12	=ASPLIT(C12:C14,"-")
M12:Q14	M12	=AFILTER(D12#,-1,)
C17:C19	C17	=AINSERT(A2:A4,"--",3,)
D17:H19	D17	=ASPLIT(C17#,"--")
M18:O20	M18	=AFILTER(D12#,1,)
C23:C25	C23	=AINSERT(A2:A4,"///",3,5)
D23:H25	D23	=ASPLIT(C23#,"///")
Dynamic array formulas.

 

[smozgur]

Note: The following Lambda functions are used in the sample mini-sheet above are explained in the following pages:
ASPLIT
AFILTER

 

[Xlambda]

Thanks a lot!!! Normally I set the links myself in the description, but I did it only if the other functions are embedded or called by the one posted. I will do this in the future. Don't want to bother.
I use them to prove the versatility of using them in dif scenario. Thanks again!!!!!✌✌

 

[smozgur]

No problem.

Since they are not native functions, anybody who copies the mini-sheet will have missing function errors if they don't know how to access the other custom functions, so it is always great to provide links for any custom functions used in the samples.

By the way, great work with the array functions!

 

[Xlambda]

Makes sense. In the minisheet above in cell H10 and Q10 I set them as links. Is ok like this or should be also in the main description area?

Thanks!! I really use them like a toolkit on daily basis.

 

[smozgur]

In the minisheet above in cell H10 and Q10 I set them as links. Is ok like this or should be also in the main description area?

It is a good idea but honestly, if I didn't notice that then I doubt others will do. There are other clickable formula cells in the mini-sheet and I even didn't notice those links.
So, although this would work, I would still list them in the descriptions.

 

[Xlambda]

I will do both in the future!! Sorry for the trouble!! The whole ecosystem is amazing!! Thanks!!

 

[smozgur]

Sorry for the trouble!!

Zero trouble