Alter my VBA date code to look for month & year instead?

[danbates]

Hi,

I have this code that finds todays date but I was wondering if it could be altered to search and select the current month and year instead?

Sub AAAAAA()

Dim C As Range
Dim Flag As Boolean
Dim D As Date

Flag = False
D = Date

    For Each c In Range("AA2:AA13")
        If C = D Then
        Flag = True
            c.Select
        End If
    Next c

If Flag = False Then
MsgBox "No Date Found"
Exit Sub
End If

End Sub

In my range I have the following and they are formatted this way as well:
Jan-21
Feb-21
Mar-21 and so on for the year.

Any help would be appreciated.

Thanks
Dan

 

[mart37]

If Month(C) = Month(D) And Year(C) = Year(D) Then

 

[Alex Blakenburg]

There are a lot of ways of doing this. Here are 2 more options.
These rely on the months in your spreadsheet being Dates and not text.

If DateSerial(Year(C), Month(C), 1) = DateSerial(Year(D), Month(D), 1) Then

If Format(C, "mmm-yy") = Format(D, "mmm-yy") Then

 

[jasonb75]

There is probably a simpler way that I'm missing, but keeping the basic structure of your original code.

Sub AAAAAA()

Dim C As Range
Dim Flag As Boolean
Dim D As Variant
Flag = False
D = [eomonth(today(),-1)+1]

    For Each C In Range("AA2:AA13")
        If C = D Then
        Flag = True
            C.Select
        End If
    Next C

If Flag = False Then
MsgBox "No Date Found"
Exit Sub
End If

End Sub

Or, using a different method

Sub BBBB()
Dim dFound As Range
Set dFound = Range("AA2:AA13").Find(Format(Date, "mmm-yy"), , xlValues, xlWhole)
If Not dFound Is Nothing Then dFound.Select Else MsgBox "Date not found"
End Sub

 

[danbates]

Hi,
Thank you all for your suggestions.
I am going to use jasonb75's second code, just because it's a smaller code and I actually understand it.

Thanks
Dan