am still learning vba - how hard would it be to create a macro that would order all the tabs by what i specify on the front page?

[bigdan]

i'm still learning VBA so dont know this. but id like to know if being able to create this program is in the cards in the next little while or is this going to be much later?

essentially i'll have a hundred or so tabs. on the front page i'd like to specify the order they should be in. and i'd like the macro to put them in that order. if there's tabs that aren't mentioned in the front page then they can do in ascending order at the end.

how difficult woudl this be?

 

[footoo]

Sub TabsSort()
Dim i&, j&
For i = 2 To Sheets.Count
    For j = 2 To Sheets.Count - 1
        If UCase(Sheets(j).Name) > UCase(Sheets(j + 1).Name) Then _
           Sheets(j).Move after:=Sheets(j + 1)
    Next
Next
On Error Resume Next
With Sheets("SheetList")
    For i = .Range("A" & Rows.Count).End(3).Row To 1 Step -1
        Sheets(.Cells(i, 1).Value).Move Before:=Sheets(2)
    Next
End With
On Error GoTo 0
End Sub

There's plenty of this sort of code available on the internet.

 

[bigdan]

Thanks! I'm afraid that didn't work though. I suppose I need to have knowledge of VBA in order to fine tune it. I put the order in the first tab, in A2 onwards, with A1 as the header. Should I have put it somewhere else?

 

[footoo]

In what way did it not work? Any error message?
Is your sheet containing the list the same as the sheet name in the macro?

 

[Peter_SSs]

I put the order in the first tab, in A2 onwards, with A1 as the header.

See if this does what you want.
Test with a copy of your workbook.

Sub ArrangeSheets()
  Dim AL As Object
  Dim itm As Variant
  Dim i As Long, NumSh As Long
  Dim shName As String
  
  Set AL = CreateObject("System.Collections.ArrayList")
  NumSh = Sheets.Count
  For i = 2 To NumSh
    AL.Add Sheets(i).Name
  Next i
  AL.Sort
  Application.ScreenUpdating = False
  With Sheets(1)
    For i = 2 To .Range("A" & Rows.Count).End(xlUp).Row
      shName = .Cells(i, "A").Value
      Sheets(shName).Move After:=Sheets(NumSh)
      AL.Remove shName
    Next i
  End With
  For Each itm In AL.ToArray
    Sheets(itm).Move After:=Sheets(NumSh)
  Next itm
  Application.ScreenUpdating = True
End Sub