Another quicky: sort reference not valid

[GS7CLW]

I get the error msg: "...sort reference not valid..."
and the ".Apply" line is highlighted. I am simply trying to select all cells
containg data and sort them by column A (5 columns are a constant):

Dim LastDataRow
LastDataRow = Range("C" & Rows.Count).End(xlUp).Row
Range("A2:G" & LastDataRow).Select
ActiveWorkbook.Worksheets("Sheet1").Sort.SortFields.Clear
ActiveWorkbook.Worksheets("Sheet1").Sort.SortFields.Add Key:=Range("A2:G" & LastDataRow) _
        , SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
With ActiveWorkbook.Worksheets("Sheet1").Sort
        .SetRange Range("A2:G" & LastDataRow)
        .Header = xlYes
        .MatchCase = False
        .Orientation = xlTopToBottom
        .SortMethod = xlPinYin
        .Apply
End With

 

[VoG]

Try

Dim LastDataRow As Long
With Sheets("Sheet1")
    LastDataRow = .Range("C" & Rows.Count).End(xlUp).Row
    .Sort.SortFields.Clear
    .Sort.SortFields.Add Key:=.Range("A2") _
        , SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
    With .Sort
        .SetRange .Range("A2:G" & LastDataRow)
        .Header = xlYes
        .MatchCase = False
        .Orientation = xlTopToBottom
        .SortMethod = xlPinYin
        .Apply
    End With
End With

 

[GS7CLW]

i get a : "wrong number of arguments or invalid property"

.SetRange.Range ("A2:G" & LastDataRow)

is highlighted

 

[VoG]

Oops!

Dim LastDataRow As Long
With Sheets("Sheet1")
    LastDataRow = .Range("C" & Rows.Count).End(xlUp).Row
    .Sort.SortFields.Clear
    .Sort.SortFields.Add Key:=.Range("A2") _
        , SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
    With .Sort
        .SetRange Sheets("Sheet1").Range("A2:G" & LastDataRow)
        .Header = xlYes
        .MatchCase = False
        .Orientation = xlTopToBottom
        .SortMethod = xlPinYin
        .Apply
    End With
End With

 

[GS7CLW]

I love that word: Oops"
I could never count how many times I have said it.

Works GREAT!!!!

Thanks
cliff