Array formula to determine changes in price and time of changes

[Legacy 332279]

Hey!

I've been looking around for a while in the forums, but haven't been able to find a solution. I'm working on an array formula that is supposed to determine when a price of an item has changed and what the new price is based on an inventory log that contains several different items. I've got the core functionality down, but I now struggle with two things:

1) I would like to omit all false values from the result, so that the resulting list doesn't contain any blank cells. I've tried using the solution provided by Aladin in this post, but I can't wrap my head around how to incorporate my array formula into that solution.

2) I would also like for the formula to include the first first registered price of an item, which the current formula omits, but again I'm unsure as to how.

This is the current array formula:

{=IF((INDEX(I:I,SMALL(IF(COUNTIF(Q3,A1:A10),ROW(A1:A10)-MIN(ROW(A1:A10))+1),ROW(INDIRECT("1:30"))))<>INDEX(I:I,SMALL(IF(COUNTIF(Q3,A1:A10),ROW(A1:A10)-MIN(ROW(A1:A10))+1),ROW(INDIRECT("2:30"))))),(INDEX(G:I,SMALL(IF(COUNTIF(Q3,A1:A10),ROW(A1:A10)-MIN(ROW(A1:A10))+2),ROW(INDIRECT("1:30"))),{1,3})))}

In essence the parent IF function checks if a row that contains data on an item (determined by an ID-number in Q3) has a different price than the previous row of data on the same item. If this is true, then it returns the time of the change (from column G) and the new price (from column I). If false, it simply returns false.

The following is the test sheet I've been using to create what I have so far (without irrelevant information):

	A	B	C	D	E	F	G	H	I
1	ID	N	Q	P	S	M	T	Q	V
2	101	...	...	...	...	...	01-01-15	...	50
3	102	...	...	...	...	...	01-01-15	...	90
4	101	...	...	...	...	...	02-01-15	...	50
5	103	...	...	...	...	...	02-01-15	...	200
6	102	...	...	...	...	...	02-01-15	...	90
7	101	...	...	...	...	...	02-01-15	...	50
8	101	...	...	...	...	...	15-01-15	...	60
9	101	...	...	...	...	...	15-01-15	...	60
10	102	...	...	...	...	...	15-01-15	...	80

<tbody>
</tbody>

Then, say if Q3 is set to 101, the following is a comparison of the current result and the desired result:

Current result

Desired result

<tbody>
</tbody>

FALSE	FALSE		01-01-15	50
FALSE	FALSE		15-01-15	60
15-01-15	60
FALSE	FALSE
#NUM!	#NUM!
#NUM!	#NUM!
#NUM!	#NUM!
#NUM!	#NUM!
#NUM!	#NUM!
#NUM!	#NUM!

<tbody>
</tbody>

Any help would be greatly appreciated!

 

[Legacy 332279]

Ok, so I figured out how to include the first registered line of data by changing the countif-function to accept both the ID number and the text string "ID".

I'm still no closer to a solution on my first issue though.

 

[Aladin Akyurek]

Row\Col

A​

B​

C​

D​

E​

F​

G​

H​

I​

J​

K​

L​

1​

ID

N

Q

P

S

M

T

Q

V

ID

101​

2​

101​

1/1/2015​

50​

date

price

3​

102​

1/1/2015​

90​

1/1/2015​

50​

4​

101​

1/2/2015​

50​

1/15/2015​

60​

5​

103​

1/2/2015​

200​

6​

102​

1/2/2015​

90​

7​

101​

1/2/2015​

50​

8​

101​

1/15/2015​

60​

9​

101​

1/15/2015​

60​

10​

102​

1/15/2015​

80​

A2:A10 is named id, G2:G10 date, and I2:I10 price.

Moreover, Ivec is defined using Formulas | Name Manager as referring to:

=ROW(price)-ROW(INDEX(price,1,1))+1

L1: 101 (An ID of interest.)

K3, control+shift+enter, not just enter, and copy down:

=IFERROR(INDEX(date,SMALL(IF(FREQUENCY(IF(price<>"",
    IF(id=$L$1,MATCH(price,price,0))),Ivec),Ivec),ROWS(K$2:K2))),"")

L3, just enter and copy down:

=IF(K3="","",INDEX(price,MATCH($K3,date,0)))

Question. Do we need to list 18-Jan-2015 if the price falls back to 50?

 

[Legacy 332279]

Thank you Aladin! A much more elegant formula than mine.

Yes, unfortunately prices can go both ways, so the formula would have to pick up that as well. Do you see any good solutions for incorporating that?

 

[Legacy 332279]

Row\Col

A​

B​

C​

D​

E​

F​

G​

H​

I​

J​

K​

L​

1​

ID

N

Q

P

S

M

T

Q

V

ID

101​

2​

101​

1/1/2015​

50​

date

price

3​

102​

1/1/2015​

90​

1/1/2015​

50​

4​

101​

1/2/2015​

50​

1/15/2015​

60​

5​

103​

1/2/2015​

200​

6​

102​

1/2/2015​

90​

7​

101​

1/2/2015​

50​

8​

101​

1/15/2015​

60​

9​

101​

1/15/2015​

60​

10​

102​

1/15/2015​

80​

<tbody>
</tbody>

A2:A10 is named id, G2:G10 date, and I2:I10 price.

Moreover, Ivec is defined using Formulas | Name Manager as referring to:

=ROW(price)-ROW(INDEX(price,1,1))+1

L1: 101 (An ID of interest.)

K3, control+shift+enter, not just enter, and copy down:

=IFERROR(INDEX(date,SMALL(IF(FREQUENCY(IF(price<>"",
    IF(id=$L$1,MATCH(price,price,0))),Ivec),Ivec),ROWS(K$2:K2))),"")

L3, just enter and copy down:

=IF(K3="","",INDEX(price,MATCH($K3,date,0)))

Question. Do we need to list 18-Jan-2015 if the price falls back to 50?

I've discovered a major problem with the formula. If you you change the value 60 in I8 (in the test sheet above) to 90, the formula will result in showing the price change as happening at 1/1/2015 instead of 1/15/2015 as it should. That is to say, the formula retrieves the date from the third row, which contains data from ID 102, instead of the eighth.

 

[Aladin Akyurek]

I've discovered a major problem with the formula. If you you change the value 60 in I8 (in the test sheet above) to 90, the formula will result in showing the price change as happening at 1/1/2015 instead of 1/15/2015 as it should. That is to say, the formula retrieves the date from the third row, which contains data from ID 102, instead of the eighth.

You are right about that. Plus we got a more funtamental problem: The same price appearing for the same id on a later date. See whether the following set up satisfies...

Row\Col

A​

B​

C​

D​

E​

F​

G​

H​

I​

J​

K​

L​

1​

ID

N

Q

P

S

M

T

Q

V

Eval

ID

101​

2​

101​

1/1/2015​

50​

50​

count

4​

3​

102​

1/1/2015​

90​

90​

date

price

4​

101​

1/2/2015​

50​

#

1/1/2015​

50​

5​

103​

1/2/2015​

200​

200​

1/15/2015​

90​

6​

102​

1/2/2015​

90​

#

1/15/2015​

60​

7​

101​

1/2/2015​

50​

#

1/30/2015​

50​

8​

101​

1/15/2015​

90​

90​

9​

101​

1/15/2015​

60​

60​

10​

102​

1/15/2015​

80​

80​

11​

101​

1/30/2015​

50​

50​

J2, control+shift+enter, not just enter, and copy down:

=IF(ISNA(MATCH(I2,$J$1:J1,0)),I2,
   IF(ISNA(MATCH(I2,$J$1:J1,0))*ISNA(MATCH($A2&"|"&$G2,$A$1:A1&"|"&$G$1:G1,0)),I2,
   IF(ISNUMBER(LOOKUP(9.99999999999999E+307,1/($A$1:A1=A2),$I$1:I1)),
   IF(LOOKUP(9.99999999999999E+307,1/($A$1:A1=A2),$I$1:I1)<>I2,I2,"#"),"#")))

L2, control+shift+enter, not just enter:

=SUM(IF(A2:A11=L1,IF(ISNUMBER(J2:J11),1)))

K4, control+shift+enter, not just enter, and copy down:

=IF(ROWS($K$2:K2)<=$L$2,INDEX($G$2:$G$11,SMALL(IF($A$2:A11=$L$1,
   IF(ISNUMBER($J$2:$J$11),ROW($G$2:$G$11)-ROW($G$2)+1)),ROWS($K$2:K2))),"")

L4, control+shift+enter, not just enter, and copy down:

=IF($K4="","",INDEX($J$2:$J$11,SMALL(IF($A$2:$A$11=$L$1,
   IF($G$2:$G$11=$K4,ROW($J$2:$J$11)-ROW($J$2)+1)),
   COUNTIFS($K$4:K4,K4))))

 

[Legacy 332279]

This seems to work perfectly, thank you! I would certainly have given up if not for this.

 

[Aladin Akyurek]

This seems to work perfectly, thank you! I would certainly have given up if not for this.

You are welcome.