Array Worksheets

[rach_oh]

I'm trying to look in every row in the same column in an array of spreadsheets. The module will run the sheets but not on the ones designated in the array. Not sure what I am missing...

Dim ws As Worksheet
Dim Pwd As Variant
Dim UpdateView As Sheets
Set UpdateView = ActiveWorkbook.Sheets(Array("Golf Input", "Maintenance Input", "F&B Input", "G&A Input", "Summary", "Golf Summary", "Maintenance Summary", "F&B Summary", "G&A Summary"))
Pwd = InputBox("Enter password to protect all sheets", "PASSWORD REQUIRED")
If Pwd = "test123" Then

'Hide unnecessary rows
With UpdateView

For Each ws In UpdateView
LineStart = 6
ColumnNumber = 2
For i = LineStart To 250

If Cells(i, ColumnNumber).Value <> "Yes" Then
Cells(i, ColumnNumber).EntireRow.Hidden = True
Else
Cells(i, ColumnNumber).EntireRow.Hidden = False
End If
Next i
Next ws
End With

 

[Peter_SSs]

You are not referencing the cells, eg Cells(i, ColumnNumber), to the particular worksheet so vba will be looking at that cell on the active sheet only every time through the loop.
It needs to be .Cells(i, ColumnNumber)
Try something like this instead.
(I would also suggest indenting your code so that it is easier to identify where individual 'blocks' start and end)

Dim LineStart As Long, ColumnNumber As Long, i As Long
Dim ws As Worksheet
Dim Pwd As Variant
Dim UpdateView As Sheets
Set UpdateView = ActiveWorkbook.Sheets(Array("Golf Input", "Maintenance Input", "F&B Input")) ', "G&A Input", "Summary", "Golf Summary", "Maintenance Summary", "F&B Summary", "G&A Summary"))
Pwd = InputBox("Enter password to protect all sheets", "PASSWORD REQUIRED")
If Pwd = "test123" Then

  'Hide unnecessary rows
  For Each ws In UpdateView
    With ws
      LineStart = 6
      ColumnNumber = 2
      For i = LineStart To 250
        .Rows(i).Hidden = .Cells(i, ColumnNumber).Value <> "Yes"
      Next i
    End With
  Next ws
End If