Auto Sorting Alphabetically VBA or other

[Avalanchez]

Hello I have a work sheet that has columns A-AZ. Each of these columns has a header with a list of names under it. I want to add a name and have it automatically alphabetized and sorted when im done typing the new name.

I have been tryin this code:

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    Range("B1", Range("B1").End(xlDown)).Sort Key1:=Range("B1"), Order1:=xlAscending, Header:=xlNo
End Sub

Which seems to do the job just fine but when I try and set it up for each column it lags super hard and errors out.
How can I use or re write this code or similar to sort all of these columns?

 

[Joe4]

Try this code instead:

Private Sub Worksheet_Change(ByVal Target As Range)
    
    Dim cl As Long
    Dim rw As Long
    
'   Only run when a single cell is manually updated
    If Target.CountLarge > 1 Then Exit Sub
    
'   Find cl where cell just updated
    cl = Target.Column
    
'   Find last row in column with data
    rw = Cells(Rows.Count, cl).End(xlUp).Row
    
'   Sort column
    Range(Cells(1, cl), Cells(rw, cl)).Sort Key1:=Cells(1, cl), Order1:=xlAscending, Header:=xlYes
    
End Sub

 

[Avalanchez]

Try this code instead:

Private Sub Worksheet_Change(ByVal Target As Range)
   
    Dim cl As Long
    Dim rw As Long
   
'   Only run when a single cell is manually updated
    If Target.CountLarge > 1 Then Exit Sub
   
'   Find cl where cell just updated
    cl = Target.Column
   
'   Find last row in column with data
    rw = Cells(Rows.Count, cl).End(xlUp).Row
   
'   Sort column
    Range(Cells(1, cl), Cells(rw, cl)).Sort Key1:=Cells(1, cl), Order1:=xlAscending, Header:=xlYes
   
End Sub

That works great!

Thanks Boss!

 

[Joe4]

You are welcome.
Glad I was able to help!