AutoSave macro

[leo89]

Hello i have and autosave macro that autosave an xls file whit data time stamp..my problem is that the macro runs only in one day..and each time i must restart Workbook to reset the Timer..i dont know that to do...maybe to change the Event..(i want this macro to autosave each day..but works only 1 day:* please Help if you want to help me my e-mail is e-mail address removed thx a lot

Private Sub Workbook_Open()
StartTimer
End Sub

Module1

Option Explicit
Public RunTime
Sub StartTimer()
Application.OnTime TimeValue("23:55:00"), "Backup"
Application.OnTime TimeValue("15:25:00"), "Backup"
End Sub

Sub Backup()
Dim sPath As String
Dim sFullPath As String
sPath = "Z:\Contorizare"
sFullPath = sPath & "\Data " & Format(Now, "dd_mm_yyyy Ora hh mm") & ".xls"
ThisWorkbook.SaveCopyAs sFullPath

End Sub

 

[AlphaFrog]

Private Sub Workbook_Open()
    [COLOR="Red"]Application.OnTime TimeValue("23:55:00"), "Backup"[/COLOR] [COLOR="Green"]'Run the macro at 23:55[/COLOR]
End Sub

Option Explicit
Sub Backup()
    Dim sPath  As String
    Dim sFullPath As String
    sPath = "Z:\Contorizare"
    sFullPath = sPath & "\Data " & Format(Now, "dd_mm_yyyy Ora hh mm") & ".xls"
    ThisWorkbook.SaveCopyAs sFullPath
    
    [COLOR="Red"]Application.OnTime TimeValue("23:55:00"), "Backup"[/COLOR][COLOR="Green"] 'Run the macro again the next day at 23:55
[/COLOR]
End Sub

 

[leo89]

If i want to use 2 timers will afect the code?

Application.OnTime TimeValue("15:25:00"), "Backup"
Application.OnTime TimeValue("23:55:00"), "Backup"

I am using a HMI (human machine interface) an OPC client and i monitoring a production site and there are two shifts..

 

[AlphaFrog]

Private Sub Workbook_Open()
    Application.OnTime TimeValue("15:25:00"), "Backup_Shift1"
    Application.OnTime TimeValue("23:55:00"), "Backup_Shift2"
End Sub

Option Explicit

Sub Backup_Shift1()
    Backup
    Application.OnTime TimeValue("15:25:00"), "Backup_Shift1"
End Sub

Sub Backup_Shift2()
    Backup
    Application.OnTime TimeValue("23:55:00"), "Backup_Shift2"
End Sub


Sub Backup()
    Dim sPath  As String
    Dim sFullPath As String
    sPath = "Z:\Contorizare"
    sFullPath = sPath & "\Data " & Format(Now, "dd_mm_yyyy Ora hh mm") & ".xls"
    ThisWorkbook.SaveCopyAs sFullPath
End Sub

 

[leo89]

Thank you for your HELP!!