Capturing Cancel of Inputbox?

[Jaymond Flurrie]

I have an inputbox where I ask user to input something. I don't accept a null string, but I have to see if he pressed cancel. How do I capture the cancel event? Right now my code looks like:

    Do While strTest = vbNullString
        strTest= InputBox("Input something", "I ask")
        If strTest= vbNullString Then
            Call MsgBox("Can't input nothing!", vbCritical, "I ask")
        ElseIf strTest= vbCancel Then
            Exit Sub
        Else
            Exit Do
        End If
    Loop

And pressing cancel result in an error or gives that "Can't input nothing!" message. How to fix it?

 

[Richard Schollar]

Hi

If you use the Application.Inputbox method rather than the Inputbox function then you will get your string holding "False" if user presses cancel rather than just an empty string.

 

[VoG]

Try like this

Sub test()
Dim inpu As Variant
inpu = Application.InputBox("Enter something")
If inpu = False Then
    MsgBox "cancelled"
ElseIf inpu = "" Then
    MsgBox "nothing entered"
Else
    MsgBox inpu
End If
End Sub

 

[Jaymond Flurrie]

Very good, thanks to both of you!

I have never thought that inputbox and application.inputbox would be something different. Well, you always learn something new!

 

[Jaafar Tribak]

You can still use the standard VBA InputBox function and tell if the user pressed the cancel Button by checking if the StrPtr of the Input String is 0.

Something like this :

Sub Test()
 
    Dim sInput As String
    
    Do
    
        sInput = InputBox("Input something", "I ask")
        
        Select Case True
        
            Case StrPtr(sInput) = 0 [B][COLOR=SeaGreen]'===> cancel[/COLOR][/B].
            
                MsgBox "You Cancelled."
                Exit Sub
            
            Case sInput = vblullstring [COLOR=SeaGreen] [B]'===> No data Input[/B][/COLOR].
            
                Call MsgBox("Can't input nothing!", vbCritical, "I ask")
            
            Case Else    [B][COLOR=SeaGreen]'===> Data input[/COLOR][/B].
            
                Exit Do
            
            End Select
        
    Loop

End Sub

 

[dk]

I think I always learn something new from your posts Jaafar

More info here on the StrPtr function if anyone's interested: http://vb.mvps.org/tips/varptr.asp

Cheers
DK

 

[Richard Schollar]

That's cool Jaafar