Changing Picture of Shapes("Image1") on Worksheet

[zeaknam]

Hi.. I have a problem.. why my image (ActiveX Image in workbooks("Logo.xls")) not changing..
VBA EXCEL 2007..
thank...


Private Sub LogoButton_Click()

Dim fs As FileDialog, myDir As String, wsLogo As Worksheet

Set fs = Application.FileDialog(msoFileDialogFilePicker)
fs.Title = "Select Your LOGO"

fs.Filters.Clear
fs.Filters.Add "Images", "*.gif; *.jpg; *.jpeg; *.bmp", 1

myDir = ThisWorkbook.Path
Workbooks.Open myDir & "\Logo.xls"
Set wsLogo = Workbooks("Logo").Sheets("LOGO")

If fs.Show = -1 Then
a = fs.SelectedItems(1)
Me.Button.Picture = LoadPicture(a)
Sheet4.Image1.Picture = LoadPicture(a) 'This ActiveX image on Thisworkbook was changing...
wsLogo.Shapes("Image1").Fill.UserPicture a 'But this ActiveX image on Workbooks("Logo") not changing...
Workbooks("Logo").Close savechanges:=True
End If

End Sub



<!-- / message -->

<!-- controls -->

 

[pgc01]

Hi
Welcome to the board

This is a simple example that loads a picture into an image activeX object, using a shape reference.
Test first a simple example like this one and then adapt to your code.

Private Sub LogoButton_Click()
Dim ws As Worksheet
Dim img As Object
Dim sImgPathname As String

sImgPathname = "c:\tmp\a.jpg"
Set ws = Worksheets("Sheet1")

Set img = ws.Shapes("Image1").OLEFormat.Object.Object

img.Picture = LoadPicture(sImgPathname)

End Sub

Does this help?

 

[zeaknam]

Private Sub LogoButton_Click()

Dim fs As FileDialog, myDir As String, wsLogo As Worksheet
Dim img as Object

Set fs = Application.FileDialog(msoFileDialogFilePicker)
fs.Title = "Select Your LOGO"

fs.Filters.Clear
fs.Filters.Add "Images", "*.gif; *.jpg; *.jpeg; *.bmp", 1

myDir = ThisWorkbook.Path
Workbooks.Open myDir & "\Logo.xls"
Set wsLogo = Workbooks("Logo").Sheets("LOGO")

If fs.Show = -1 Then
a = fs.SelectedItems(1)
Me.Button.Picture = LoadPicture(a)
Sheet4.Image1.Picture = LoadPicture(a)
set img = wsLogo.Shapes("Image1").OLEFormat.Object.Object
img.Picture = LoadPicture(a)
Workbooks("Logo").Close savechanges:=True
End If

End Sub



And it's DONE!!!..... Thankyou....

 

[pgc01]

You're welcome. Thanks for the feedback.