Check box, and multiple =IF formuals in 1 cell

[topher1166]

I have several checkbox options. I am trying to have a certain link appear in 1 cell depending on what check box is selected (I would like the option to have multiple links in the 1 cell).

I am having 2 problems:

1. I can't seem to get multple =IF statements in the single cell (1 =IF per check box)

2. I cant get a hyper link inside the IF statement.

ex.

=IF(A1=True, "HyperlinkHere", "")

A1 is the cell attached to the check box true/false statement.

 

[Jerry Sullivan]

Here are two approaches for you to consider. In order to demonstrate multiple IF statements, the examples assume that you want to use one of 3 possible links depending on whether A1 is True/False and whether B1 is greater than 10.

Option 1 puts the multiple IF statements in the same cell as the Hyperlink (B2). The =Hyperlink should be the outside function instead of having the if statements on the outside.

Excel Workbook
	A	B
1	TRUE	8
2		Message 1
Option 1

Excel 2007

Cell Formulas
Range	Formula
B2	=HYPERLINK(IF(A1=TRUE,"C:\TEST1\File 1.pdf",(IF(B1>10,"C:\TEST2\File 1.doc","C:\TEST3\File 1.xls"))),IF(A1=TRUE,"Message 1",(IF(B1>10,"Message 2","Message 3"))))

Option 2 keeps cell B2 with the Hyperlink simple. It uses references to other cells that have the multiple IF statements resulting in parameters for Path, File and Message to be displayed.

Excel Workbook
	A	B	C	D	E
1	FALSE	8	C:\TEST 3\	File3.xls	Message 3
2		Message 3
Option 2

Excel 2007

Cell Formulas
Range	Formula
C1	=IF(A1=TRUE,"C:\TEST 1\",(IF(B1>10,"C:\TEST 2\","C:\TEST 3\")))
D1	=IF(A1=TRUE,"File 1.pdf",(IF(B1>10,"File 2.doc","File3.xls")))
E1	=IF(A1=TRUE,"Message 1",(IF(B1>10,"Message 2","Message 3")))
B2	=HYPERLINK(C1&D1,E1)