Click to add, Click to remove

[christianbiker]

Greetings all,

I am wondering if there is a way to specify that when any empty cell in a specific range is clicked on that an "x" populate that cell, and the same thing in reverse...if a cell in the same range is clicked that has an "x" that the "x" be removed and the cell is now blank again?

Any help would be appreciated.

Thanks,
Chad

 

[VoG]

Try this: right click the sheet tab, select View code and paste in

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
If Intersect(Target, Range("A3:F5")) Is Nothing Then Exit Sub
Select Case Target.Value
    Case "x": Target.ClearContents
    Case "": Target.Value = "x"
End Select
End Sub

Change the range to suit.

 

[taurean]

Not tested sufficiently:

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
Dim r As Range
Set r = Range("A1:A10")
Set rsect = Application.Intersect(r, Target)
If Not rsect Is Nothing Then
    Select Case Target.Value2
    Case ""
    Target.Value2 = "X"
    Case "X"
    Target.Value2 = ""
    End Select
End If
End Sub

 

[christianbiker]

I used VoG's code below and it works great, however I have noticed that I cannot clear the entire range that this code is used for by selecting all cells and clearing. This is part of a form that other people will be completing and I need to have a reset function built in for them as a macro if they want to clear it.

How can I get around that issue?

Thanks,
Chad

 

[VoG]

Try

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
If Target.Count > 1 Then Exit Sub
If Intersect(Target, Range("A3:F5")) Is Nothing Then Exit Sub
Application.EnableEvents = False
Select Case Target.Value
    Case "x": Target.ClearContents
    Case "": Target.Value = "x"
End Select
Application.EnableEvents = True
End Sub

 

[christianbiker]

One word...AWE SOME!!!!

Thanks!