Combo and Text Boxes

[Rocky0201]

Hi...

I have a Userform with approx. 50 combination of Textbox's, ComboBox's and ListBox's. When running code in the UserForm, is there a way that I can list the name of all of the Textbox's, ComboBox's and ListBox's?

In other words:

For i = 1 to The number of Box's

Do code

Next

I have an array setup, BoxArray, with box number of the Text, Combo and List box's. I'm looking to loop through the array and when I have a match to a box, execute some code.

Thanks.

 

[p45cal]

try some of the following ways of looping through controls on a userform:

Sub blah1()
UserForm3.Show False
For Each ctrl In UserForm3.Controls
    If TypeName(ctrl) = "ComboBox" Then MsgBox ctrl.Name    '(others are "ListBox" and "TextBox")
Next ctrl
End Sub

Sub blah2()
With UserForm3
    .Show False
    cbAry = Array(.ComboBox1, .ComboBox2, .ComboBox3, .ComboBox4, .ComboBox5)
    tbAry = Array(.TextBox1, .TextBox2, .TextBox3, .TextBox4, .TextBox5)
    lbAry = Array(.ListBox1, .ListBox2, .ListBox3, .ListBox4)
    For Each ctrl In cbAry
        Debug.Print ctrl.Name
    Next ctrl
End With
End Sub

Sub blah3()
With UserForm3
    .Show False
    cbAry = Array("ComboBox1", "ComboBox2", "ComboBox3", "ComboBox4", "ComboBox5")
    tbAry = Array("TextBox1", "TextBox2", "TextBox3", "TextBox4", "TextBox5")
    lbAry = Array("ListBox1", "ListBox2", "ListBox3", "ListBox4")
    For Each nm In cbAry
        Debug.Print .Controls(nm).Name'.Controls(nm).value
    Next nm
End With
End Sub

Sub blah4()
With UserForm3
    .Show False
    For i = 1 To 5
        Debug.Print .Controls("ComboBox" & i).Value
    Next i
End With
End Sub

 

[Rocky0201]

This is Great!!!!

Thanks p45cal...

 

[Rocky0201]

p45cal...

Is it possible to target just the page that I am on?

My UserForm1 has three pages. If I am on Page 1, can I just see the box's (Text, Combo, List) for the page that I am on? Is it possible to loop through just those box's and not all box's from the other two pages?

I stopped my app at a point where I can use Watch. I see we where I can use UserForm1.Control but I don't see how to drill down to the MultiPage that I is current using the same For loop that you have presented.

Thanks you very much for the help.

 

[p45cal]

the likes of:
For Each ctrl In UserForm3.MultiPage1.Pages(0).Controls
Pages on a 3 page multipage are numbered 0 to 2.

You can use the name of the page instead, default is like:
For Each ctrl In UserForm3.MultiPage1.Pages("Page1").Controls

current page is:
For Each ctrl In UserForm3.MultiPage1.Pages(UserForm3.MultiPage1.Value).Controls

 

[Rocky0201]

Thanks Much p45cal!!!

I'll post again once I get my code fixed to handle the new process.