CommandBar Help

[Adoh]

Hi,

This is my first post, and this is probably a simple question

I am trying to create a toolbar which has a commandControlEdit(textfield)
and a commandControlButton(button)

I want a message box to pop up and give the name of the text in the text field.

BUT whenever i click the the button the text dissapears.

and my onAction method cannot capture the text befor it disappears


Can anyone Help

 

[DominicB]

Good evening Adoh

I don't believe this is possible.

It's very annoying because the Microsoft knowledge base says that an msoControlEdit box is simply an msoControlComboBox without the dropdown facility, but the user response from this type of control can be captured fairly easily.

Is an msoControlComboBox acceptable?

HTH

DominicB

 

[Andrew Poulsom]

If you press Enter or Tab before clicking the button, the entry will stick.

 

[DominicB]

Hi Andrew

If you press Enter or Tab before clicking the button, the entry will stick.

...but how do you actually capture it...?

DominicB

 

[Adoh]

Hi DominicB,

To capture it,
I set the .onaction in the commandcontroledit

to a function i declare and pass the index

here is an example of how i did it:

13 is th id of the textfield
.OnAction = "'IDTables_Find """ & 13 & """'"


Sub IDTables_Find(textfields As Integer)

If textfields = 13 Then
findtext = CommandBars(thisButtonCaption).Controls(textfields).Text
End If


But i still do not know how to get it using the command button


end sub

 

[Andrew Poulsom]

This worked for me:

Sub AddBar()
    Dim CB As CommandBar
    Dim CBC As CommandBarControl
    Set CB = CommandBars.Add
    With CB
        .Name = "MyBar"
        .Visible = True
        Set CBC = .Controls.Add(msoControlEdit)
        With CBC
            .Tag = "MyEdit"
        End With
        Set CBC = .Controls.Add(msoControlButton)
        With CBC
            .Tag = "MyButton"
            .Style = msoButtonIconAndCaption
            .Caption = "Get Text"
            .OnAction = "GetText"
        End With
    End With
End Sub

Sub GetText()
    MsgBox CommandBars("MyBar").FindControl(Type:=msoControlEdit, Tag:="MyEdit").Text
End Sub