Conditional Formatting Macro Help

[ponderance]

I used to have a macro that did the following formulas automatically - I feel like a part of my brain was overwritten with something else because VBA looks like a foreign language to me these days

=$G1>”H*" (the backgrounds in rows with this would be red.)

=$N1>"PS*" (the backgrounds in rows with this would be green.)

=$N1>"CS*" (the backgrounds in rows with this would be green.)

=$AC2<1 (the backgrounds in rows with this would be light grey.)

seems so simple, but i can't figure out how to do it with all the google and youtube trials i've done. right now i have a macro to sort by fields, a macro to color backgrounds, manually select, and get through it that way. I might have had individual macros for each of the 4 color-by-value portions, but it's going on 3 years now.

 

[rlv01]

One example.

Sub SetFormatConditionsExample()
    Dim FCRange As Range
    Dim FormulaStr As String
    Dim WS As Worksheet
    
    Set WS = ActiveSheet                    'define worksheet containing format conditions.
    
    'a) Define the range for conditional formatting
    With WS
        Set FCRange = .Range("A1:A10").EntireRow  'this is an example. Modify to use your own range.
    End With
    
    With FCRange.FormatConditions
        'b1) Delete the existing format conditions
        .Delete

        'c1) Define formula1
        FormulaStr = "=$G1 > " & """" & "H*" & """"         'Any formula that resolves to True or False"
        Debug.Print FormulaStr
        
        'd1) Add the new FormatCondition and define the formatting
        With .Add(Type:=xlExpression, Formula1:=FormulaStr)
            .StopIfTrue = True
            .Interior.Color = vbRed
        End With
        
        'c2) Define formula2
        FormulaStr = "=$N1 > " & """" & "PS*" & """"         'Any formula that resolves to True or False"
        Debug.Print FormulaStr
        
        'd2) Add the new FormatCondition and define the formatting
        With .Add(Type:=xlExpression, Formula1:=FormulaStr)
            .StopIfTrue = True
            .Interior.Color = vbGreen
        End With
        
        'c3) Define formula3
        FormulaStr = "=$N1 > " & """" & "CS*" & """"         'Any formula that resolves to True or False"
        Debug.Print FormulaStr
        
        'd3) Add the new FormatCondition and define the formatting
        With .Add(Type:=xlExpression, Formula1:=FormulaStr)
            .StopIfTrue = True
            .Interior.Color = vbGreen
        End With
        
        'c4) Define formula4
        FormulaStr = "=$AC1 > 1"         'Any formula that resolves to True or False"
        Debug.Print FormulaStr
        
        'd4) Add the new FormatCondition and define the formatting
        With .Add(Type:=xlExpression, Formula1:=FormulaStr)
            .StopIfTrue = True
            .Interior.Color = RGB(211, 211, 211) 'light gray
        End With
        
    End With
End Sub