Copy the selected range and paste it in reverse

[sofas]

Hello, I have this code to select several rows and copy them to the last row on column f
The default number of columns is always 2, meaning I select a specific number of rows from columns (F) and (G) and copy them. What I want is when copying, column F is copied into G and vice versa for column G, as in the attached image

Sub macro()
Selection.Copy

With Sheet1.Range("F" & Rows.Count).End(xlUp).Offset(1, 0)
      .PasteSpecial xlPasteValues
   End With

End Sub

 

[rlv01]

Would something like this work?

Sub macro()
    Dim ColA, ColB
   
    With Selection
        If .Columns.Count = 2 Then
            ColA = .Columns(1).Value
            ColB = .Columns(2).Value
           
            .Columns(1).Value = ColB
            .Columns(2).Value = ColA
        End If
    End With
End Sub

 

[sofas]

Hello, is there any suggestion to implement the order?
@rlv01
Thank you, but the problem is that it reverses the original data. Because the idea is to copy the specified range and paste it in reverse, taking into account that I am working on a table

 

[Peter_SSs]

Try this with a copy of your workbook

Sub macro_v2()
  Dim rws As Long
  
  rws = Selection.Rows.Count
  Cells(Rows.Count, Selection.Column).End(xlUp).Offset(1).Resize(rws, 2).Value = Application.Index(Selection, Evaluate("row(1:" & rws & ")"), Array(2, 1))
End Sub

 

[sofas]

Try this with a copy of your workbook

Sub macro_v2()
  Dim rws As Long
  
  rws = Selection.Rows.Count
  Cells(Rows.Count, Selection.Column).End(xlUp).Offset(1).Resize(rws, 2).Value = Application.Index(Selection, Evaluate("row(1:" & rws & ")"), Array(2, 1))
End Sub

Thank you, it works very well. But I noticed that if there is a value in one of the adjacent columns, the data is pasted after the last row. Empty You must copy after the last row of column F, ignoring the presence of a value in other columns, for example, knowing that the data is in a table

 

[Peter_SSs]

But I noticed that if there is a value in one of the adjacent columns, the data is pasted after the last row.

Well, that is exactly what your code in post 1 does too and your only question was how to reverse the columns, so that is what I did.

Try ..

Sub macro_v3()
  Dim nextrw As Long
  
  With Selection
    nextrw = .EntireColumn.Find(What:="?*", Searchorder:=xlByRows, Searchdirection:=xlPrevious).Row + 1
    .Offset(nextrw - .Row).Value = Application.Index(Selection, Evaluate("row(1:" & .Rows.Count & ")"), Array(2, 1))
  End With
End Sub

 

[sofas]

Well, that is exactly what your code in post 1 does too and your only question was how to reverse the columns, so that is what I did.

Try ..

Sub macro_v3()
  Dim nextrw As Long
  
  With Selection
    nextrw = .EntireColumn.Find(What:="?*", Searchorder:=xlByRows, Searchdirection:=xlPrevious).Row + 1
    .Offset(nextrw - .Row).Value = Application.Index(Selection, Evaluate("row(1:" & .Rows.Count & ")"), Array(2, 1))
  End With
End Sub

Great, thank you. This is what is really needed

 

[Peter_SSs]

Cheers. You're welcome.