Copy value from a webpage into a variable

[reniantony]

Hello Excel Experts! Need your help on a simple automation program.

There is a website where it has some data and I need to put it into a variable and get it displayed. In more detail, my program accesses the NSE website to the stock name, and I need the % DQTQ value to be fetched into the variable and displayed on the screen.

The code seems to run well, but the problem is that the DQTQ value is never captured, its always blank. I've mentioned the code and the snapshot of the ID below.

The code is as follows:

=============================
Sub dqtq()

Dim driver As New WebDriver
Dim stockname As String
Dim dqtq As String
Dim dqtq1 As String

stockname = InputBox("Please enter Stockname", "Input stockname")
driver.Wait (500)
driver.Start "chrome"
'driver.Window.Minimize

driver.Wait (1000)
driver.Get "https://www.nseindia.com/get-quotes/equity?symbol=" & stockname

driver.Wait (1000)

dqtq = driver.FindElementById("securityWiseDQTQ").Value

driver.FindElementById("securityWiseDQTQ").ScrollIntoView

MsgBox "DQTQ is " & dqtq

End Sub
=============================

 

[Saurabhj]

Hi,

Use below code.

'This program requires references to the following in Tools -> References: (see image)
'1 Microsoft Internet Controls
'2. Microsoft HTML Object Library

Sub getStockData()
    On Error Resume Next
    Application.ScreenUpdating = False
    Dim HTMLDoc As New HTMLDocument
    Dim ieBrowser As New InternetExplorer
    Dim qtyTraded As String, dQ As String, DQTQ As String
    Dim stock As String
    
    stock = InputBox("Enter Stock Code")
    
    'To open and show Internet Explorer
    'ieBrowser.Visible = True
    
    'To Open website in Internet Explorer
    ieBrowser.navigate "https://www.nseindia.com/get-quotes/equity?symbol=" & stock
    
    Do
    ' Wait till the Browser is loaded
    Loop Until ieBrowser.readyState = READYSTATE_COMPLETE
    
    Set HTMLDoc = ieBrowser.document
    
    Application.Wait (Now + TimeValue("00:00:03"))
      
    qtyTraded = HTMLDoc.getElementById("securityWiseQT").innerHTML
    dQ = HTMLDoc.getElementById("securityWiseDQ").innerText
    DQTQ = HTMLDoc.getElementById("securityWiseDQTQ").innerText

    ActiveSheet.Range("A2") = stock
    ActiveSheet.Range("B2") = qtyTraded
    ActiveSheet.Range("C2") = dQ
    ActiveSheet.Range("D2") = DQTQ
    
    MsgBox "Data Copied"
    Set ieBrowser = Nothing
    Set HTMLDoc = Nothing
    
    Application.ScreenUpdating = True
End Sub

 

[reniantony]

Thanks a lot for the answer!
This helped me a lot!