Copying a cell from one worksheet to another conditionally

[misslisa330]

Hi. Please help! In my workbook, I have a worksheet called Request Tracker, where in column F, I have a drop down to select Yes or No. I want it to work where, if I select Yes from the drop down in column F, the info in columns B, D, and E of that same row in gets copied to a different sheet in the same workbook called Publication Tracker, to columns B, E, and F, respectively, and in the next available row. Note: I don't want to copy the whole row from one sheet to the other, just the cells noted, as the two sheets otherwise have different info. (Added images, if that's helpful)

I'm new to VBA and I've tried a few things based on my Google searches, and it's not working. Thanks, in advance!

 

[mumps]

Copy and paste this macro into the worksheet code module. Do the following: right click the tab name for your Requests sheet and click 'View Code'. Paste the macro into the empty code window that opens up. Close the code window to return to your sheet. Make a selection in column F.

Private Sub Worksheet_Change(ByVal Target As Range)
    If Target.CountLarge > 1 Then Exit Sub
    If Target.Column <> 6 Then Exit Sub
    Application.ScreenUpdating = False
    If Target = "Yes" Then
        With Sheets("Publication Tracker")
            .Cells(.Rows.Count, "B").End(xlUp).Offset(1).Value = Target.Offset(, -4).Value
            .Cells(.Rows.Count, "E").End(xlUp).Offset(1).Resize(, 2).Value = Array(Target.Offset(, -2).Value, Target.Offset(, -1).Value)
        End With
    End If
    Application.ScreenUpdating = True
End Sub

 

[misslisa330]

That works!! Thank you SOOO much, mumps!!

 

[mumps]

You are very welcome.

 

[misslisa330]

Actually one other question, please. If I want to also enter the value, Mailbox, in column D along with the fields I'm copying to the Publication Tracker sheet, how do I add that?

 

[misslisa330]

Actually one other question, please. If I want to also enter the value, Mailbox, in column D along with the fields I'm copying to the Publication Tracker sheet, how do I add that?

Oh, I figured it out... Not to worry. Thanks, again, for your help!!