Copying from Word to Excel

[sbyers2]

I am trying to copy a word document into an excel tab, but if i just do it directly it populates across, and if i paste special as a word file, it leaves certain paragraphs out....any suggestions? Also, a side question. I have a large file with 100 or so tabs. All are protected, but I noticed a mistake and need to fix it on each tab. Is it possible to unprotect all of them at once? or do I have to do each one individually

 

[xapie128]

Also, a side question. I have a large file with 100 or so tabs. All are protected, but I noticed a mistake and need to fix it on each tab. Is it possible to unprotect all of them at once?

Create and run a macro with the following:

    For index = 1 To Worksheets.Count
      Worksheets(index).Unprotect
    Next

You can change all worksheets back to protected by changing the "Unprotect" to "Protect" and running it again.

 

[VoG]

If the data in the Word doc is in tables then the following macro will import correctly into Excel.

Sub ImportWordTable()
Dim wdDoc As Object
Dim wdFileName As Variant
Dim TableNo As Integer 'table number in Word
Dim iRow As Long 'row index in Excel
Dim iCol As Integer 'column index in Excel
wdFileName = Application.GetOpenFilename("Word files (*.doc),*.doc", , _
"Browse for file containing table to be imported")
If wdFileName = False Then Exit Sub '(user cancelled import file browser)
Set wdDoc = GetObject(wdFileName) 'open Word file
With wdDoc
TableNo = wdDoc.tables.Count
If TableNo = 0 Then
MsgBox "This document contains no tables", _
vbExclamation, "Import Word Table"
ElseIf TableNo > 1 Then
TableNo = InputBox("This Word document contains " & TableNo & " tables." & vbCrLf & _
"Enter table number of table to import", "Import Word Table", "1")
End If
With .tables(TableNo)
'copy cell contents from Word table cells to Excel cells
For iRow = 1 To .Rows.Count
For iCol = 1 To .Columns.Count
Cells(iRow, iCol) = WorksheetFunction.Clean(.cell(iRow, iCol).Range.Text)
Next iCol
Next iRow
End With
End With
Set wdDoc = Nothing
End Sub

Unfortunately I can't remembere who first posted this so I can't give them the credit.