Counting Unique text and numeric values with date range

[successken]

I am finding many posting on this topic with unique numeric values and have not come across one in regards to a text value. The essence of the formula is looking through a list for unique email addresses and now I need to up it to a date range and eventually a store # range

I am using the following array formula to establish an overall count:
=SUM(IF(FREQUENCY(IF(LEN('[Data - Deliverables.xlsb]orders'!A2:A5000)>0,MATCH('[Data - Deliverables.xlsb]orders'!A2:A5000,'[Data - Deliverables.xlsb]orders'!A2:A5000,0),""), IF(LEN('[Data - Deliverables.xlsb]orders'!A2:A5000)>0,MATCH('[Data - Deliverables.xlsb]orders'!A2:A5000,'[Data - Deliverables.xlsb]orders'!A2:A5000,0),""))>0,1))
Ctrl+Shift+Enter

The date column is E:E.
The store number column is G:G
Thank you for any input.

 

[Aladin Akyurek]

Substitute

'[Data - Deliverables.xlsb]orders'

for X in the following:

=SUM(IF(FREQUENCY(IF(X!A2:A5000<>"",
   IF(X!E2:E5000>=J2,IF(X!E2:E5000<=K2,
    IF(X!G2:G5000=L2,MATCH(X!A2:A5000,X!A2:A5000,0))))),
     ROW(X!A2:A5000)-ROW(X!A2)+1),1))

where J2 and K2 houses date criteria of interest with J2 <= K2 and L2 a store of interest.

You could also do a SQL query to obtain the required result (The board has some posts by Fazza on this.).

 

[successken]

The more I work on this project the more I realize I need to learn SQL query.

Thank you that does appear to work very well.

How much of a burden will I put on excel if I were to change the end of range number from 5000 to 500000?

Again thank you.

 

[Aladin Akyurek]

The more I work on this project the more I realize I need to learn SQL query.

Thank you that does appear to work very well.

You are welcome. Thanks for providing feedback.

How much of a burden will I put on excel if I were to change the end of range number from 5000 to 500000?
...

That would be considerable indeed given the number of conditions involved.