Create a code that doesn't differentiate between capital and small letters

[Fredrik1987]

Hi!

I'm wondering if there's a way to create a simple VBA code that interprent a name, indifferently it starts with a capital letter or not. I've been searching around a little, and haven't really found anything.

For instance:
Column A consist of names (Hans, Gretel etc.). Where each name correspons to a value in column B (1, 2... etc.)
What I want the script to understand, is that if I insert "hans" instead of "Hans", the meaning are the same.
Also, is there a way to include misspelling (e.g. ahns instad of Hans)

Column A	Column B
Hans	1
hans	1
ahns	1

<tbody>
</tbody>

This is just a simplified example of a large script, I think I read somewhere that it is possible to script in such a way that VBA only looks for the letters in a word, indepent of their arragement?

 

[Peter_SSs]

... the code you're refering to would be immensely useful for later use

Put all this in a standard module and run the 'CompareWords' macro

Sub CompareWords()
  Dim sWords As String, word1 As String, word2 As String, alpha1 As String, alpha2 As String
  Dim Bits1, Bits2
  Dim sMsg As String
  
  sWords = Application.InputBox("Enter two wors separated by a comma")
  sMsg = " : do not have the same letters"
  word1 = Split(LCase(sWords), ",")(0)
  word2 = Split(LCase(sWords), ",")(1)
  If Len(word1) = Len(word2) Then
    Bits1 = Split(StrConv(word1, vbUnicode), ChrW(0))
    Bits2 = Split(StrConv(word2, vbUnicode), ChrW(0))
    alpha1 = bubSort(Bits1)
    alpha2 = bubSort(Bits2)
    If alpha1 = alpha2 Then sMsg = " : have the same letters"
  End If
  MsgBox sWords & sMsg
End Sub


Function bubSort(ary) As String
  Dim tmp As String
  Dim i As Long, j As Long, lMin As Long, lMax As Long
  
  lMin = LBound(ary)
  lMax = UBound(ary)
  For i = lMin To lMax - 1
    For j = i + 1 To lMax
      If ary(i) > ary(j) Then
        tmp = ary(i)
        ary(i) = ary(j)
        ary(j) = tmp
      End If
    Next j
  Next i
  bubSort = Join(ary, "")
End Function

 

[Fredrik1987]

That's great!! I will implement it as soon as possible!