Dice Roll

[Monitor]

I have tried many different functions to get a text response when I roll - 1,1,1,1,1 or 2,2,2,2,2 using five dice. The table has 100 rows and the numbers are random. I've tried if, Vlookup, Hlookup and or.

 

[d'Holbach]

Another one:

=STDEV(A1:E1)=0

 

[oldbrewer]

Bravo !

 

[oldbrewer]

=IF(STDEV(A2:E2)=0,"hooray","")

I claim no credit for this......

 

[shg]

StDev is a big function for a small problem ...

 

[d'Holbach]

Of course it is and I'm definitely not suggesting for OP to use it. The original question was answered on the first page and we were just having fun with providing alternative and creative solutions.

 

[shg]

Oh -- in that case,

=IF((INDEX(LINEST(A2:E2,,,TRUE),1,1)=0)*(INDEX(LINEST(A2:E2,,,TRUE),3,1)=1), "Hooray", "")

 

[bschwartz]

FYI - Summary:

Excel 2010

	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q	R	S	T
1	A	B	C	D	E	Shg 1	Shg 2	d'Holbach 1	d'Holbach 2	d'Holbach 3	Shg 3	Pcg01 1	Rick Rothstein 1	d'Holbach 4	Bertie 1	d'Holbach 5	RoryA 1	Ingolf 1	d'Holbach 6	Shg 4
2	1	1	1	1	1	Hooray	Hooray	TRUE	Success	Success	Success	Success	Hooray!	Success	success	Success	Hooray	URA	TRUE	Hooray
3	2	2	2	2	2	Hooray	Hooray	TRUE	Success	Success	Success	Success	Hooray!	Success	success	Success	Hooray	URA	TRUE	Hooray
4	8	8	8	8	8		Hooray	FALSE	Success	Success	Success	Success	Hooray!	Success	success	Success	Hooray	URA	TRUE	Hooray
5	1	2	3	4	5			FALSE	Fail	Fail	Fail	Fail		Failure	success	Failure		UUUF	FALSE
6	1	1		11	1			FALSE	#DIV/0!	Fail	Fail	Fail	Hooray!	Failure	success	Failure		UUUF	FALSE	#VALUE!
7	2	1	3	1	3			FALSE	Success	Fail	Fail	Fail		Failure	fail	Failure		URA	FALSE
8	5	4	8	9	7			FALSE	Fail	Fail	Fail	Fail		Failure	success	Failure		UUUF	FALSE

<colgroup><col style="width: 25pxpx"><col><col><col><col><col><col><col><col><col><col><col><col><col><col><col><col><col><col><col><col></colgroup><thead>
</thead><tbody>
</tbody>

Sheet70​

Worksheet Formulas Cell Formula H2 =OR(COUNTIF(A2:E2,1)=5,COUNTIF(A2:E2,2)=5) I2 =IF(SUMPRODUCT(1/COUNTIF(A2:E2,A2:E2))<>5,"Success","Fail") K2 =IF(COUNTIF(A2:E2,A2)<>5,"Fail","Success") L2 =IF(COUNTIF(A2:D2,E2)<>4,"Fail","Success") M2 =IF(A2&B2&C2&D2&E2=A2&A2&A2&A2&A2,"Hooray!","") N2 =IF(DELTA(A2,B2),IF(DELTA(C2,D2),IF(DELTA(E2,D2),"Success","Failure"),"Failure"),"Failure") O2 =IF(MOD(SUM(A1:E1),5)=0,"success","fail") P2 =IF(DELTA(A2,B2),IF(DELTA(C2,D2),IF(DELTA(E2,D2),IF(DELTA(B2,C2),"Success","Failure"),"Failure"),"Failure"),"Failure") Q2 =REPT("Hooray",MIN(A2:E2)=MAX(A2:E2)) R2 =IF(SUM(A2:E2)=A2*5,"URA","UUUF") S2 =STDEV(A2:E2)=0 T2 =IF((INDEX(LINEST(A2:E2,,,TRUE),1,1)=0)*(INDEX(LINEST(A2:E2,,,TRUE),3,1)=1), "Hooray", "") <thead> </thead><tbody> </tbody>

<tbody>
</tbody>

Array Formulas Cell Formula F2 {=IF(OR(AND(A2:E2=1), AND(A2:E2=2)),"Hooray","")} G2 {=IF(AND(A2:E2 = TRANSPOSE(A2:E2)),"Hooray","")} J2 {=IF(COUNTIF(A2:E2,A2:E2)<>5,"Fail","Success")} <thead> </thead><tbody> </tbody> Entered with Ctrl+Shift+Enter. If entered correctly, Excel will surround with curly braces {}. Note: Do not try and enter the {} manually yourself

<tbody>
</tbody>

 

[bschwartz]

A few more...

=IF(AVEDEV(A2:E2)=0,"Hooray!","")

=IF(DEVSQ(A2,B2,C2,D2,E2)=0,"Hooray!","")

=IF(MIN(A2:E2)=MAX(A2:E2),"Hooray!","")

=IF(VAR.P(A2:E2)=0,"Hooray!","")

Array formula:

=IF(AND(CHOOSE({1,2,3,4,5},A2,A2,A2,A2,A2)=A2:E2),"Hooray!","")

 

[Monitor]

Confirmed with Ctrl+Shift+Enter:

=IF(OR(AND(A1:E1=1), AND(A1:E1=2)),"Hooray","")

I used your idea from your last formula and this time it worked. I just had to add a few more ands Thanks