Double Click Ambiguous Error

[bamaisgreat]

I am unsure how to combined the 2 macros below so I want get a error. Thanks for the Help

Private Sub Worksheet_BeforeDoubleClick _
 (ByVal Target As Range, Cancel As Boolean)


 Dim isect As Object


 'Test if target in required range
 Set isect = Application.Intersect(Target, Range("M5:P34"))


 If Not isect Is Nothing Then
 'Cancel Edit mode invoked by double click
 Cancel = True


 'Test if cell already contains check mark
 If ActiveCell = Chr(252) Then
 'Clear check mark
 ActiveCell.ClearContents
 Else
 'Insert check mark code
 ActiveCell = Chr(252)
 'Change font to Wingdings
 With ActiveCell.Characters _
 (Start:=1, Length:=1).Font


 .Name = "Wingdings"


 End With
 End If
 End If


 End Sub


Private Sub Worksheet_BeforeDoubleClick( _
            ByVal Target As Range, Cancel As Boolean)
    Dim rInt As Range
    Dim rCell As Range


    Set rInt = Intersect(Target, Range("L5:L34"))
    If Not rInt Is Nothing Then
        For Each rCell In rInt
            rCell.Value = "FCM"
        Next
    End If
    Set rInt = Nothing
    Set rCell = Nothing
    Cancel = True
End Sub

 

[Norie]

Try this

Private Sub Worksheet_BeforeDoubleClick _
 (ByVal Target As Range, Cancel As Boolean)
Dim isect As Object
Dim rInt As Range
Dim rCell As Range

    'Test if target in required range
    Set isect = Application.Intersect(Target, Range("M5:P34"))


    If Not isect Is Nothing Then
        'Cancel Edit mode invoked by double click
        Cancel = True

        'Test if cell already contains check mark
        If Target.Value = Chr(252) Then
            'Clear check mark
            Target.ClearContents
        Else
            'Insert check mark code
            Target.Value = Chr(252)
            'Change font to Wingdings
           Target.Font.Name = "Wingdings"
        End If
    End If

    Set rInt = Intersect(Target, Range("L5:L34"))

    If Not rInt Is Nothing Then
        Cancel = True
        For Each rCell In rInt
            rCell.Value = "FCM"
        Next
    End If
    Set rInt = Nothing
    Set rCell = Nothing
    
End Sub

 

[mikerickson]

You could test the cell clicked this way

Private Sub Worksheet_BeforeDoubleClick _
 (ByVal Target As Range, Cancel As Boolean)

    If Not Intersect(Target, Range("M5:P34")) Then
        ' code for checkmark
        Cancel = True
    ElseIf Not Intersect(Target, Range("L5:L34") Then
        ' code for PCM
        Cancel = True
    End If
End Sub

BTW, the loop for the PCM is not needed, since one cannot DoubleClick on more than one cell at a time.