Duplicate whole row

[zubair009]

https://app.box.com/s/lj3y3wcdr1ru1k2kvav2

Hi,
I have this data in 500 rows I want to border color with difference random color row wise i am also trying in vba but could not do it. if i select row from A TO F and then start macro it should color all smilir rows with one color and if row does not have smilar row then only one color.

Thank you so much if you can solve my problem.

regards

 

[Andrew Poulsom]

Please post some sample data rather than an image, to avoid a lot of typing.

 

[zubair009]

Thanks a lot for your response sample data is here in below link please. regards.

https://app.box.com/s/sho6bunbj54lchhakbjb

 

[Andrew Poulsom]

Try:

Sub ColourDuplicates()
    Dim Rng As Range
    Dim Colour As Long
    Dim Formula1 As String
    Dim r As Long
    Dim c As Long
    Dim CountOne As Long
    Dim Formula2 As String
    Dim First As Long
    Set Rng = Range("C3").CurrentRegion
    Rng.Interior.ColorIndex = xlNone
    Colour = 3
    With Rng
        For r = 1 To .Rows.Count
            Formula1 = ""
            For c = 1 To .Columns.Count
                Formula1 = Formula1 & .Columns(c).Resize(r).Address & "," & .Cells(r, c).Address & ","
            Next c
            Formula1 = "=COUNTIFS(" & Left(Formula1, Len(Formula1) - 1) & ")"
            CountOne = .Parent.Evaluate(Formula1)
            If CountOne = 1 Then
                .Rows(r).Interior.ColorIndex = Colour
                Colour = Colour + 1
            Else
                Formula2 = ""
                For c = 1 To .Columns.Count
                    Formula2 = Formula2 & "(" & .Columns(c).Address & "=" & .Cells(r, c).Address & ")*"
                Next c
                Formula2 = "=MATCH(1,(" & Left(Formula2, Len(Formula2) - 1) & "),FALSE)"
                First = .Parent.Evaluate(Formula2)
                .Rows(r).Interior.ColorIndex = .Cells(First, 1).Interior.ColorIndex
            End If
        Next r
    End With
End Sub

 

[zubair009]

I love it, you are a super star since three months I am trying to do this but could not do this, I have tried to do it in my dream but even though I failed to do it.

Thank you mate. I am very very exited. you have made my weekend. Wish you all the best. GOD BLESS YOU. regards