Re: R1C1

Anything appearing within [ ] is a relative adjustment

Consider: Active Cell is B10

R[-5]C[1]

equates to C5 as we subtract five rows from current row (10) and add 1 column to current column (2)

R[5]C[-1]

equates to A15 as we add five rows to current row and subtract one column from current column (ie move left)

Any numbers that follow R/C that are not encased within [ ] are essentially "absolutes"

R4C[1]

equates to C4 .. ROW is fixed to row 4 but Column is a relative adjustment (+1)

If you applied the same formula to B11 you would still get C4 (row does not adjust)... if you applied the same formula to say A11 you would get B4 - the row remains fixed but the column adjustment is relative so becomes B (A + 1 column)

If no values follow the R/C then the current position is used...

RC

is equivalent to saying B10

R:R

is equivalent to saying 10:10

C:C

is equivalent to saying B:B

So going to your example:

=SUMIF(R1C44:R[-2]C44,RC44,R1C:R[-2]C)

You're using Ranges that always start in Row 1 (absolute) but where end row is relative to current row less 2 rows... the Columns are fixed for the initial Criteria range in the SUMIF but the Sum column is relative to the column in which the formula appears... if we assume for sake of demo that the first formula in the 5 x 5 matrix is going in AS100 then the above translates as:

=SUMIF($AR$1:$AR98,$AR100,AS$1:AS98)

The formula when applied say to the 2nd row and 2nd column of the 5 x 5, ie AT101 would be translated as follows:

=SUMIF($AR$1:$AR99,$AR101,AT$1:AT99)

So you see as the formula is pasted across the matrix of results the formulae will be begin to reference prior results (ie rows 100+) but as long as AR100:AR104 are unique it's not an issue as the values won't meet the SUMIF criteria and thus won't be included in the results.

I hope that helps.