Encorporate data in http POST request

[Tejas Kore]

Hello Friends,

I am trying to fetch data from one of our vendor's site(https://developer.tenable.com/reference#exports-vulns-request-export) using API. I saw the api documentation but there weren't any examples using VBA. Here is a code snippet from python:

import requests

url = "https://cloud.tenable.com/vulns/export"

payload = {"filters": {
        "tag.<category>": ["tag.CompanyName External Assets: IP"],
        "last_found": 1625570746
    }}
headers = {
    "Accept": "application/json",
    "Content-Type": "application/json",
    "X-ApiKeys": "" #Cannot disclose publicly
}

response = requests.request("POST", url, json=payload, headers=headers)

print(response.text)

Here is my VBA code:

Sub authenticated_test()
    Dim req As MSXML2.ServerXMLHTTP60
    Dim JsonString As String
    Dim dic As Variant
    Dim liveURL As String, paperURL As String
    Dim acc_header_name, acc_header_value, secret_header_name, secret_key As String
    
    Set req = New MSXML2.ServerXMLHTTP60
    
    acc_header_name = "Accept"
    acc_header_value = "application/json"
    secret_header_name = "X-ApiKeys"
    secret_key = "" 'Cannot disclose the key on public
    
    liveURL = "https://cloud.tenable.com"
    paperURL = "https://cloud.tenable.com/vulns/export"
    
    req.Open "POST", paperURL, False
    req.setRequestHeader acc_header_name, acc_header_value
    req.setRequestHeader secret_header_name, secret_key
    req.send ["filters", "tag.<category>", ["tag.CompanyName External Assets: IP"], "last_found", 1625570746] '---> Need help here
    'Debug.Print req.responseText
    Set dic = ParseJSON(req.responseText)
    Debug.Print ListPaths(dic)
End Sub

I need help here '--->.
I tried to print the response. It says 'obj.error --> Unsupported Media Type'. Basically I am trying to apply filters and fetch data. It would be great if anyone could let me know the mistake I am making.
Notes: 1. Using ParseJSON function to parse the JSON string received ('Excel VBA: Parse JSON, Easily).
2. last_found is UNIX time.

 

[John_w]

Try this:

    Dim payload As String
    payload = """filters"": { ""tag.<category>"": [""tag.CompanyName External Assets: IP""], ""last_found"": 1625570746 }"
    With req
        .Open "POST", paperURL, False
        .setRequestHeader "Accept", "application/json"
        .setRequestHeader "Content-Type", "application/json"
        .setRequestHeader "X-ApiKeys", secret_key
        .send payload
        Debug.Print .responseText
    End With

 

[Tejas Kore]

Try this:

    Dim payload As String
    payload = """filters"": { ""tag.<category>"": [""tag.CompanyName External Assets: IP""], ""last_found"": 1625570746 }"
    With req
        .Open "POST", paperURL, False
        .setRequestHeader "Accept", "application/json"
        .setRequestHeader "Content-Type", "application/json"
        .setRequestHeader "X-ApiKeys", secret_key
        .send payload
        Debug.Print .responseText
    End With

Got this:
{"statusCode":400,"error":"Bad Request","message":"Invalid request payload JSON format"}

 

[John_w]

I've just looked at your API link, and the Python example shows no payload data is sent:

response = requests.request("POST", url, headers=headers)

Therefore try one of these:

.send
.send vbNullString

 

[Tejas Kore]

I've just looked at your API link, and the Python example shows no payload data is sent:

response = requests.request("POST", url, headers=headers)

Therefore try one of these:

.send
.send vbNullString

That's because no payload was selected. For e.g. .. Just below the python code .. You can observe *num_assets .. If you enter a value in the box next to it .. It will add the payload.

 

[John_w]

OK, I see. I don't know what the syntax for Python strings is and omitted the first { and last } in your original post, assuming they are string delimiters. Try it with them added back:

    payload = "{""filters"": { ""tag.<category>"": [""tag.CompanyName External Assets: IP""], ""last_found"": 1625570746 }}"

 

[Tejas Kore]

OK, I see. I don't know what the syntax for Python strings is and omitted the first { and last } in your original post, assuming they are string delimiters. Try it with them added back:

    payload = "{""filters"": { ""tag.<category>"": [""tag.CompanyName External Assets: IP""], ""last_found"": 1625570746 }}"

Yupps .. I tried that .. It work .. Thanks a lot .. Seems we need to add those curly brackets at the beginning and end to make it a complete JSON string .. I used ..

payload = "{" & """filters"": { ""tag.<category>"": [""CompanyName External Assets""], ""last_found"": 1625570746 }" & "}"